如何停止（）主线程NSApp 运行（）事件循环？（嵌入在 C++ 中）

Question

这是一个最小的可重现示例，如果阅读时间太长，请转到下一部分的问题，然后在需要时浏览代码。

最小示例：

假设一个简单的 C++ 命令行：

main.cpp

#include <iostream>
#include "Wrapper.h"
int main()
{
    Wrapper wrapper;
    wrapper.run();
    std::cout << "Exiting" << std::endl;
}

Objective-C包装器header：Wrapper.h

struct OCWrapper;
class Wrapper
{
public:
    Wrapper() noexcept;
    virtual ~Wrapper() noexcept;
    void run();
private:
    OCWrapper* impl=nullptr;
};

它的实现：Wrapper.mm

#import "Wrapper.h"
#import "MyOCApp.h"

struct OCWrapper
{
    MyOCApp* wrapped=nullptr;
};

Wrapper::Wrapper() noexcept: impl(new OCWrapper)
{
    impl->wrapped = [[ MyOCApp alloc] init];
}

Wrapper::~Wrapper() noexcept
{
    [impl->wrapped release];
    delete impl;
}

void Wrapper::run()
{
    [impl->wrapped run];
}

最后是有趣的部分，在 Objective-C、MyOCApp.h:

#import <AppKit/AppKit.h>
#import <Foundation/Foundation.h>

@interface MyOCApp: NSObject
@end

@implementation MyOCApp
- (id)init 
{
    [[NSNotificationCenter defaultCenter] addObserver:self
                selector:@selector(applicationDidFinishLaunching:)
                name:NSApplicationDidFinishLaunchingNotification object:nil];
    
    return self;
}

- (void)run
{
    [self performSelector:@selector(shutdown:) withObject:nil afterDelay: 2];
    //CFRunLoopRun();
    
    [NSApplication sharedApplication];
    [NSApp run];
}

- (void) shutdown:(NSNotification *) notif
{
    NSLog(@"Stopping");
    //CFRunLoopStop(CFRunLoopGetCurrent());
    [NSApp stop:self];
}

- (void) applicationDidFinishLaunching:(NSNotification *) notif
{
    NSLog(@"Application ready");
}
@end

CMakeLists.txt

cmake_minimum_required (VERSION 3.10.0)
cmake_policy( SET CMP0076 NEW)

set(CMAKE_CXX_STANDARD 17)

project(ocapp)

add_executable(${PROJECT_NAME})

find_library(APP_KIT AppKit)
find_library(CORE_FOUNDATION CoreFoundation)
target_link_libraries( ${PROJECT_NAME} ${APP_KIT} ${CORE_FOUNDATION} )

target_sources( ${PROJECT_NAME} PRIVATE "main.cpp" "Wrapper.mm" PUBLIC "Wrapper.h" "MyOCApp.h" )

可以使用以下命令构建项目：

$ cmake -G Xcode .
$ open ocapp.xcodeproj

问题：

当使用 [NSApp run] 和 [NSApp stop:self] 时，我无法停止事件循环，因此它会无限期地保持运行。

Application finished launching
Stopping
.....
Killed: 9

当使用 CFRunLoopRun() 和 CFRunLoopStop(CFRunLoopGetCurrent()) 时，它 start/stop 正确，但 applicationDidFinishLaunching 永远不会被触发。

Stopping
Terminating

问题：

这是为什么？以及如何同时使用这两个功能？

Answer 1

问题不在附加的代码中。您现有的变体

[NSApplication sharedApplication];
[NSApp run];

和

[NSApp stop:self];

正确。

罪魁祸首是你的CMakeLists.txt。您包含的那个创建了一个可执行二进制文件。这对于控制台应用程序来说很好，但它不是由 AppName.app 文件夹和一堆其他文件组成的有效 MacOS 应用程序。由于您使用的 AppKit API 没有适当的 MacOS 应用程序脚手架，因此它不起作用。

您的 CMakeLists.txt 中的 最低限度修正 是：

add_executable(
    ${PROJECT_NAME}
    MACOSX_BUNDLE
)

现在您将在 Xcode 中拥有正确的 App 目标。更多适合MacOS应用的高级范例可以在网上查找CMakeLists.txt

更新
所以我进一步调查并检查了
中的退出例程 -[NSApplication run]（+[NSApp run] 是为了兼容性而保留的同义词，但真正的实现是在 -[NSApplication run] 中）。我们可以像这样通过 lldb 设置一个符号断点： b "-[NSApplication run]" 感兴趣的片段（对于 X86-64）是：

->  0x7fff4f5f96ff <+1074>: add    rsp, 0x98
    0x7fff4f5f9706 <+1081>: pop    rbx
    0x7fff4f5f9707 <+1082>: pop    r12
    0x7fff4f5f9709 <+1084>: pop    r13
    0x7fff4f5f970b <+1086>: pop    r14
    0x7fff4f5f970d <+1088>: pop    r15
    0x7fff4f5f970f <+1090>: pop    rbp
    0x7fff4f5f9710 <+1091>: ret

我们可以验证箭头指向的断点仅在捆绑变体中命中，而在“裸”可执行变体中未命中。经过进一步研究，我发现这个答案非常有帮助。 @Remko 的关键引用是：

it seems that the UI loop stop request is only processed after a UI event (so not just after a main loop event).

确实如此。如果在“裸”可执行变体中我们添加

- (void) shutdown:(NSNotification *) notif
{
    NSLog(@"Stopping");
    //CFRunLoopStop(CFRunLoopGetCurrent());
    [NSApp stop:self];
    [NSApp abortModal]; //this is used for generating a UI NSEvent
}

我们得到了期望的行为，应用程序正常终止。因此，您的“裸”应用程序变体不是正确的 MacOS 应用程序，因此它不会收到 UI 事件（无论如何，它的运行循环都可以正常工作）。

另一方面，具有 Info.plist 等的适当 MacOS 应用程序包对于 MacOS 设置应用程序 window、Dock 图标等是必要的

总而言之运行如果您根本不需要 AppKit，我建议要么选择纯控制台应用程序，要么按照书本做事。否则你会运行变成这样的异常。

如何停止（）主线程NSApp 运行（）事件循环？（嵌入在 C++ 中）

How to stop() main thread NSApp run() event loop? (embedded in C++)

objective-c++

nsapplication

最小示例：

问题：

问题：

如何停止（）主线程NSApp 运行（）事件循环？ （嵌入在 C++ 中）

How to stop() main thread NSApp run() event loop? (embedded in C++)

objective-c++

nsapplication

最小示例：

问题：

问题：

如何停止（）主线程NSApp 运行（）事件循环？（嵌入在 C++ 中）