如果与 Excel 中的公式匹配，则突出显示特定单元格

Question

我在 Excel 中输入了以下公式。如何突出显示满足条件的特定cell/cells？这里突出显示的列是D、E、F，而X列与条件要求有关。

=IF(
    OR(
        AND(D5>X12,E5>X29),
        AND(D5>X12,F5>X45),
        AND(E5>X29,F5>X45),
        AND(D5<X16,E5<X33),
        AND(D5<X16,F5<X49),
        AND(E5<X33,F5<X49)),
    "YES",
    "NO")

“是”或“否”会出现在特定的列中，例如在 I 列中。但我想突出显示哪个单元格符合条件，例如 D5>X12、E5>X29 如果都符合条件则两者都 D5和 E5 应该突出显示为红色。如果只有一个符合条件，则不应突出显示任何人。

Answer 1

你的大公式可以重写：

=IF(
     OR(SUM(D5>X12,E5>X29,F5>X45)>1,SUM(D5<X16,E5<X33,F5<X49)>1),
     "YES",
     "NO")

您必须在 3 个不同的单元格或列中输入 3 个不同的公式。

主页 -> 条件格式 -> 管理规则... ->

新规则... -> 选择“使用公式确定要设置格式的单元格”
粘贴公式：=OR(AND(SUM($D5<$X16,$E5<$X33,$F5<$X49)>1,$D5<$X16),AND(SUM($D5>$X12,$E5>$X29,$F5>$X45)>1,$D5>$X12))

点击“格式...”并选择格式。
确定 -> 适用于 =$D
申请

新规则... -> 选择“使用公式确定要设置格式的单元格”
粘贴公式：=OR(AND(SUM($D5<$X16,$E5<$X33,$F5<$X49)>1,$E5<$X33),AND(SUM($D5>$X12,$E5>$X29,$F5>$X45)>1,$E5>$X29))

点击“格式...”并选择格式。
确定 -> 适用于 =$E
申请

新规则... -> 选择“使用公式确定要设置格式的单元格”
粘贴公式：=OR(AND(SUM($D5<$X16,$E5<$X33,$F5<$X49)>1,$F5<$X49),AND(SUM($D5>$X12,$E5>$X29,$F5>$X45)>1,$F5>$X45))

点击“格式...”并选择格式。
确定 -> 适用于 =$F
申请

好的

如果与 Excel 中的公式匹配，则突出显示特定单元格

Highlight the particular cell if matches the formula in Excel

excel

conditional-formatting

worksheet-function

excel-formula