SAPGUI 未显示 long_text 或未处理的自定义异常的文本

Question

在 SAP NetWeaver 7.52 中，我创建了一个基于 ABAP 分类的异常，它在 report/program 中的 try catch 子句中执行时运行良好。但当异常未被 try catch 子句处理时，自定义消息不会显示在 SAPGUI 中。

我正在寻找的是，当没有定义 try catch 时，引发语句时使用的导出消息显示在“UNCAUGHT_EXCEPTION”中。我尝试重新定义 get_text( ) 和 get_longtext( ) 方法。但是 ABAP 运行时间错误不会向开发人员提供有关原因的任何有用信息（存储在异常的“attr_message”属性中）。

当使用“try catch”时，可以毫无问题地检索消息，但想法是 SAPGUI 在“ABAP 运行time Error”报告中向开发人员提供正确的消息。

zcx_adk_exception.abap

"! Base exception for all ABAP Development Kit (ADK) exceptions
class zcx_adk_exception definition public create public inheriting from cx_dynamic_check.

    public section.
        "! Initializes the exception message
        "! @parameter message    | Message related to the reason of the exception
        methods constructor
            importing value(message) type zadk_str optional.

        "! Returns the message associated to the exception
        methods get_message
            returning value(result) type zadk_str.

        methods if_message~get_text redefinition.

        methods if_message~get_longtext redefinition.

        private section.
            data attr_message type zadk_str value ''.

endclass.

class zcx_adk_exception implementation.

    method constructor ##ADT_SUPPRESS_GENERATION.
        super->constructor(  ).
        if message is not initial.
            me->attr_message = message.
        endif.
    endmethod.

    method get_message.
        result = me->attr_message.
    endmethod.

    method if_message~get_text.
        result = me->get_message(  ).
    endmethod.

    method if_message~get_longtext.
        result = me->get_message(  ).
    endmethod.

endclass.

什么工作正常：

try.
    raise exception type zcx_adk_exception exporting message = 'Base_Exception_Error'.
catch zcx_adk_exception into data(ex).
    write: / 'Example 1:', ex->get_message(  ).
    write: / 'Example 2:', ex->get_text(  ).
    write: / 'Example 2:', ex->get_longtext(  ).
endtry.

输出是这样的：

什么不起作用：

" Not Catching the exception
raise exception type zcx_adk_exception exporting message = 'Base_Exception_Error'.

这会导致显示以下消息

Answer 1

TL;DR : SAP 不打算允许开发人员自定义短转储。

“短转储”是ABAP内核在ABAP程序中发生意外错误时生成的报告，即由于程序中的错误（通常是未捕获的异常，或不可捕获的异常）引起的错误错误）或系统故障（input/output 资源、内存资源等）

旨在帮助开发者分析错误原因并进行修正。

它不是故意生成的，除非开发人员在理论上不可能但实际上发生了，并且被认为需要很多信息来分析它是否发生，因此是一个简短的转储。

如果您真的打算生成带有消息的简短转储，出于某种目的，有两种方法：

MESSAGE 'message text' TYPE 'X'.（常用于标准SAP程序，特别是更新功能模块）
RAISE SHORTDUMP ... 或 ... THEN THROW SHORTDUMP ... 条件表达式。两者都存在于 ABAP 7.53 之后。例如RAISE SHORTDUMP TYPE zcx_adk_exception EXPORTING message = 'Base_Exception_Error'.

短转储将包含分析部分中的消息文本。

Answer 2

根据之前提出的使用消息的想法，我想出了以下代码，允许通过消息引发异常。这允许异常在“try catch”块中调用时显示正确的消息，并在 SAPGUI 生成的转储的“错误分析”部分中显示有用的消息。

解法：

"! Program to test functionalities and utilities
REPORT zsandbox_tests.


" Exception Class
CLASS lcl_exception DEFINITION INHERITING FROM cx_dynamic_check.
  PUBLIC SECTION.
    INTERFACES if_t100_dyn_msg.
    METHODS if_message~get_text REDEFINITION.
    METHODS constructor
      IMPORTING VALUE(message) TYPE string.

  PRIVATE SECTION.
    DATA attr_message TYPE string VALUE ''.
ENDCLASS.

CLASS lcl_exception IMPLEMENTATION.
  METHOD if_message~get_text.
    result = attr_message.
  ENDMETHOD.

  METHOD constructor.
    super->constructor(  ).
    me->attr_message = message.
  ENDMETHOD.
ENDCLASS.



" Class that raises the exception
CLASS lcl_main DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS main RAISING lcl_exception.
ENDCLASS.
CLASS lcl_main IMPLEMENTATION.
  METHOD main.
    DATA raise_message TYPE string VALUE 'Custom Message for the Exception'.
    RAISE EXCEPTION TYPE lcl_exception
        MESSAGE e000(lcl_exception) WITH raise_message '' '' '' " The if_t100_dyn_msg supports 4 attributes: V1, V2, V3 and V4 but I only use the first one
        EXPORTING message = raise_message.

  ENDMETHOD.
ENDCLASS.


" Call to Main Method
START-OF-SELECTION.

  TRY.
      lcl_main=>main( ).
    CATCH lcl_exception INTO DATA(ex).
      WRITE ex->get_text(  ).
  ENDTRY.

这会生成以下输出：

不使用try catch时:

" Call to Main Method
start-of-selection.
  lcl_main=>main( ).

这是输出：

SAPGUI 未显示 long_text 或未处理的自定义异常的文本

SAPGUI not displaying long_text or text for unhandled custom exceptions

oop

exception

abap

sap-gui

netweaver