如何在 QML 中更改 TreeView 的行选择颜色？

Question

下面的代码会产生这样的结果：

我不知道蓝色是从哪里来的。如何在 TreeView 中设置选中行的背景颜色？

import QtQuick 2.2
import QtQuick.Controls 1.5
import QtQuick.Controls.Styles 1.4
import QtQml.Models 2.2
import filesystem_browser 1.0

ApplicationWindow
{
    visible: true
    width: 740
    height: 740

    Rectangle
    {
        anchors.centerIn: parent
        color: "#292A38"
        border.color: "#373848"
        height: 600; width: 600

        ItemSelectionModel
        {
            // This model is comming from C++' class DisplayFileSystemModel.
            model: treeViewModel
        }

        TreeView
        {
            id: view
            anchors.fill: parent
            anchors.margins: 2 * 12
            model: treeViewModel
            rootIndex: root
            selection:
                ItemSelectionModel
                {
                    model: treeViewModel

                    onSelectionChanged:
                    {
                        console.log( treeViewModel.data( view.currentIndex ))
                    }
                }

            style:
                TreeViewStyle
                {
                    backgroundColor: "#14161C"
                    highlightedTextColor: "red"
                    alternateBackgroundColor: "#14161C"
                }

            TableViewColumn
            {
                title: "Name"
                role: "display"
                resizable: true
            }

            itemDelegate:
                    Rectangle
                    {
                       color: "transparent"
                       height: 20

                       Rectangle
                       {

                           height: 20; width: 40; color: styleData.depth ? "green":"transparent";
                           anchors.right: parent.right
                           border.width: 1
                       }

                       Text
                       {
                           color: styleData.depth ? "green":"black";
                           anchors.verticalCenter: parent.verticalCenter
                           text: styleData.value
                       }
                   }
            }
    }
}

Answer 1

在 TreeView 中添加一个 rowDelegate 以指定如何绘制行：

TreeView {
    // ...
    rowDelegate: Rectangle {
        color: styleData.selected ? "red" : "transparent"
    }
}

如何在 QML 中更改 TreeView 的行选择颜色？

How to change row selection colour of TreeView in QML?

qt

qml

qtquick2