Gnuplot 倾斜数据

Question

我的数据有偏差，我尝试绘制数据的等高线和彩色图。下图显示了没有范围限制的数据。

我只想绘制 xrange [0.55:0.95] 和 yrange [0:10] 中的数据。我的问题是我在绘图范围之外有彩色地图三角形。见下图。

我的代码如下：

#reset session

FILE = "data_sensibilite_correlation_Tpfr_CH"

set contour
set cntrparam level discrete 0.5, 1, 1.5, 2, 2.5, 3

set xrange [0:10]
set yrange [0.55:0.95]
set cbrange [0:4]
set table $Contour
    splot FILE u 1:2:3
unset table

set style textbox opaque
unset key
set view
#set xrange [0:10]
#set yrange [0.55:0.95]
set cbrange [0:4]
set xlabel "{/Symbol e}_{/Symbol q} [%]"
set ylabel "T_b / T_{w hs}"
set cblabel "{/Symbol e}_{{/Symbol F} hs} [%]"
plot FILE u 1:2:3 w image, \
     $Contour u 1:2 index 1::1 w l lc "red", \
     '' u 1:2:3 index 1::1 every ::0::0 w labels boxed
### end of code

我的数据可以在这里找到：https://filesender.renater.fr/?s=download&token=6eadae73-9f7c-4983-90ca-5406ac8796bb。

我试图修改我的数据，以便只保留所需范围内的点，但数据不再是网格数据，在这种情况下我无法成功绘制等高线。

有人可以向我解释如何在希望的范围内绘制数据而不会在范围外出现三角形吗？

非常感谢，马丁

Answer 1

此答案需要最新的 gnuplot 版本，版本 5.4.1

而不是 plot ... with image，使用 splot ... with pm3d。这是修改后的脚本和相应的输出。

set contour base
set cntrparam level discrete 0.5, 1, 1.5, 2, 2.5, 3
set cntrlabel onecolor interval 40

set xrange [0:10]
set yrange [0.55:0.95]
set cbrange [0:4]

set style textbox opaque
unset key
set view map
set xlabel "{/Symbol e}_{/Symbol q} [%]"
set ylabel "T_b / T_{w hs}"
set cblabel "{/Symbol e}_{{/Symbol F} hs} [%]"

set pm3d noborder

splot FILE u 1:2:3 w pm3d, \
      FILE u 1:2:3 w l lc "red" nosurface, \
      FILE with labels boxed

Gnuplot 倾斜数据

Gnuplot skewed data

plot

gnuplot

contour

colormap