为什么数组公式不适用于整列？

Question

我在 this sheet 的单元格 F1 和 G1 中有一个公式。我想保留单元格 F/G8 和 F9&G9 中的文本，但它给我一个错误。请注意，公式位于数组中，因此它可以追溯应用于列中的所有单元格。

这是单元格 F1 中使用的代码：

=ARRAYFORMULA(IFNA(VLOOKUP(B2:B, QUERY('Raw Logs'!C2:F, "select C,sum(F) group by C label sum(F)''"), 4, 0)))

这是单元格 G1 中使用的代码：

=ARRAYFORMULA(IFNA(VLOOKUP(B2:B, QUERY('Raw Logs'!C2:H, "select C,sum(H) group by C label sum(H)''"), 6, 0)))

此外，单元格 C1 中公式中的数据不再填充（以前是）- 错误说不能，因为它无法覆盖 C9，但是 C9 中早先有文本，数据来自公式仍在填充。

这是单元格 C1 中使用的公式：

=ArrayFormula(IFERROR(VLOOKUP(B:B,'Roster Registrations'!F1:G,2,FALSE)))

关于如何解决这个问题的任何提示？

Answer 1

数组公式需要 space 才能推出 - 这就是原因。如果你想运行它从第一行删除单元格 F8:F9 并使用：

={"";"";"";"";"";"";"";"Total for February"; 
 "Activity"&CHAR(10)&"Hours"; ""; 
 ARRAYFORMULA(IFNA(VLOOKUP(B11:B&"", TEXT(QUERY('Raw Logs'!C2:F*1, 
 "select Col1,sum(Col4) 
  where Col1 is not null 
  group by Col1 
  label sum(Col4)''"), {"@", "[h]:mm:ss"}), 2, 0)))}

对于 G1 fx 删除 G9 并在 G1 中使用它：

={"";"";"";"";"";"";"";""; 
 "Number of"&CHAR(10)&"Tests"; ""; 
 ARRAYFORMULA(IFNA(VLOOKUP(B11:B, QUERY('Raw Logs'!C2:H*1, 
 "select Col1,sum(Col6) 
  where Col1 is not null 
    and Col1 <> 0
  group by Col1 
  label sum(Col6)''"), 2, 0)))}

为什么数组公式不适用于整列？

Why isn't the array formula applying to the entire column?

formula

google-sheets

google-sheets-formula