使用符号函数安装递归函数

Question

可以使用 symbol-function（而不是 defun）以编程方式在 Common Lisp 中安装函数：

* (setf (symbol-function 'factorial)
    (compile nil (lambda (n) 
                   (if (= n 1) 
                     1 
                     (* n (factorial (- n 1)))))))

; in: SETF (SYMBOL-FUNCTION 'FACTORIAL)
;     (FACTORIAL (- N 1))
;
; caught STYLE-WARNING:
;   undefined function: COMMON-LISP-USER::FACTORIAL
;
; compilation unit finished
;   Undefined function:
;     FACTORIAL
;   caught 1 STYLE-WARNING condition
#<FUNCTION (LAMBDA (N)) {1003F2222B}>

但是和上面一样，如果函数是递归的，SBCL 会发出警告，因为函数是匿名的。

使用 defun 时不会遇到此问题，因为正如 hyperspec 所说： “计算 defun 导致函数名成为 lambda 表达式指定的函数的全局名称”。

在使用 symbol-function 时可以通过提供正确的函数名称来避免警告吗？

(PS: 起初我以为compile函数可以给函数名，但那只是宏。)

Answer 1

声明 factorial 是 fbound 足以删除警告：

(compile nil 
         (lambda (n) 
           (declare (ftype function factorial)) 
           (if (= n 1) 
               1 
               (* n (factorial (- n 1))))))

Answer 2

你可以使用my define-functions hack，但一般的技巧是你需要告诉系统这个东西是一个函数，而且你通常需要globally ] 以及函数体内，所以编译器不会在稍后调用这个东西时抱怨。这就是 define-function / define-functions 安排要做的事情。如果你想手工做，你可能想要这个：

(declaim (ftype function factorial))
(setf (fdefinition 'factorial) (compile nil ...))

这几乎就是 define-function 扩展成的内容（实际上它扩展成 define-functions 然后为它工作）。

请注意，您可以将函数的名称指定给compile：这与宏无关。但是，您仍然会收到相同的警告：

(compile 'fact (lambda (n)
                 (if (= n 1) 
                     1 
                     (* n (fact (- n 1))))))

会将函数安装为 fact 的 fdefinition，但编译器在编译函数时并不知道。

Answer 3

使用局部递归函数可能会有用

CL-USER 2 > (setf (symbol-function 'factorial)
                  (compile nil
                           (lambda (n)
                             (labels ((%factorial (n)
                                        (if (= n 1) 
                                            1 
                                          (* n (%factorial (- n 1))))))
                                   (%factorial n)))))
#<Function 13 40600030D4>

CL-USER 3 > (factorial 4)
24

这样一来，递归调用的去向就很清楚了。

可以将其隐藏在某种命名的 lambda 宏后面。可以这样使用：

(compile nil 
         (nlambda factorial (n) 
           (if (= n 1) 
               1 
               (* n (factorial (- n 1))))))

使用符号函数安装递归函数

Installing a Recursive Function Using symbol-function

lambda

sbcl

common-lisp

anonymous-function