vb.net 中 MS Access 数据库中的行数

Question

有谁知道哪里出了问题吗？
我正在尝试计算 MS 访问数据库中的行数。

这是我试过的代码：

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load

    Dim conn As New OleDbConnection
    conn.ConnectionString = ("Provider=Microsoft.ACE.OLEDB.12.0;Data Source=F:\Test Database\Database.accdb")
    conn.Open()
    Dim strsql As String
    strsql = "Select count(*) from TABLA"             '" select Panel from PANELS where ID"
    Dim cmd As New OleDbCommand(strsql, conn)
    Dim myreader As OleDbDataReader

    myreader = cmd.ExecuteReader
    myreader.Read()
    PanelsInDatabase = myreader.Item(strsql)
    Label1.Text = PanelsInDatabase
    conn.Close()

    For i As Integer = 0 To PanelsInDatabase - 1
        CreatePanels()
        CreateDeleteButton(_PanelName)
        CreateLabels(_PanelName)
        CreateLabel2(_PanelName)
    Next

End Sub

如果我开始代码，我得到一个错误：

System.IndexOutOFRangeException

Answer 1

选择单个值时使用 ExecuteScalar

    Dim connStr = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=F:\Test Database\Database.accdb"
    Dim sql = "select count(*) from tabla"        

    Using cmd As New OleDbCommand(sql, New OleDbConnection(connStr))
      cmd.Connection.Open()
      Dim ct = CInt(cmd.ExecuteScalar())

    End Using

Answer 2

我已将您的用户界面代码与数据库代码分开。当然，我不知道CreatePanels在做什么，也不知道_PanelName是从哪里来的。在您的 UI 代码中，您调用 GetTABLACount 函数，该函数 returns 作为整数。

在数据库代码中使用 Using...End Using 连接和命令块，因此即使出现错误也能正确处理它们。

由于您只是检索单条数据，因此可以使用.ExecuteScalar，其中returns结果集第一行的第一列为Object。使用 CInt 得到 Integer.

Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
    Dim count = GetTABLACount()
    Label1.Text = count.ToString
    For i As Integer = 0 To count - 1
        CreatePanels()
        CreateDeleteButton(_PanelName)
        CreateLabels(_PanelName)
        CreateLabel2(_PanelName)
    Next
End Sub

Private Function GetTABLACount() As Integer
    Dim dbCount As Integer
    Using conn As New OleDbConnection("Provider=Microsoft.ACE.OLEDB.12.0;Data Source=F:\Test Database\Database.accdb"),
            cmd As New OleDbCommand("Select count(*) from TABLA", conn)
        conn.Open()
        dbCount = CInt(cmd.ExecuteScalar)
    End Using
    Return dbCount
End Function

vb.net 中 MS Access 数据库中的行数

count of rows in MS access database in vb.net

vb.net

ms-access-2010