试图计算总工资

Question

我正在尝试创建一个程序来计算每周员工的总工资。

这是我的代码

(princ"Enter working hours: ")
(defparameter workhours(read))
(if (and (>= workhours 0)) (<= workhours 60))
    (princ"Enter hourly pay rate: ")
    (defparameter HPrate(read))
    (if(<= workhours 40)
        (* workhours HPrate))

我在 lisp 中构建这个 40*HPrate + (workhours - 40) * HPrate * 1.5 有困难

这是公式

(Regular hours/week) Gross Pay = Hours X Rate
(With Overtime) Over Time Pay = ( Hours - 40 ) X Rate X 1.5
Gross Pay = 40 X Rate + Over Time Pay

Answer 1

您应该尝试将代码的逻辑与 input/output 操作分开，例如询问数字或写入结果。通常最好只编写给定数字和输出数字的函数。然后，您可以从任何类型的用户界面（图形或文本）调用它。

业务逻辑

您想根据工作时间和小时费率计算总工资。

所以你定义了一个函数，命名为gross-pay，它的输入是work-hours和一个hourly-rate:

(defun gross-pay (work-hours hourly-rate)
  10000 ;; a lot of money, just for testing
  )

现在已经定义好了，你可以调用它，你的环境会自动打印结果：

* (gross-pay 0 0)
10000

您的代码中的一个问题是您有一个 if 分支，其中包含一个测试和三个分支，这不是有效的语法。根据你写的内容，我猜你想要这样的逻辑：

(defun gross-pay (work-hours hourly-rate)
  (assert (<= 0 work-hours 60))
  ;; ...
  )

assert 检查条件是否成立，否则发出错误信号。我认为如果小时数小于零或大于 60，则没有有效的计算，在这种情况下出现错误是有意义的。

然后，你想用你给的公式计算总工资。

您必须计算正常工时数、加班工时数，并对两种工时进行不同定价（并求和）。

我们定义一个辅助函数，split-time，其中returns两个值，小时数小于或等于40，剩余时间（超过40）：

(defun split-time (hours)
  (if (> hours 40)
      ;; the regular amount is maxed to 40
      ;; overtime is the rest
      (values 40 (- hours 40))
      ;; regular amount is the same as the input
      ;; no overtime
      (values hours 0)))

使用multiple-value-bind可以得到多个values的结果，如下：

(defun gross-pay (work-hours hourly-rate)
  (assert (<= 0 work-hours 60))
  (multiple-value-bind (regular overtime) (split-time work-hours)
    ;; here regular and overtime are bound to values
    ))

最后：

(defun gross-pay (work-hours hourly-rate)
  (assert (<= 0 work-hours 60))
  (multiple-value-bind (regular overtime) (split-time work-hours)
    (+ (* regular  hourly-rate)
       (* overtime hourly-rate 3/2))))

在这里，我使用3/2而不是1.5，因为浮点计算是近似的，但有理数是精确的。例如，结果可以在打印时转换回浮点数。

测试

现在你已经有了一个功能，你可以测试它：

* (gross-pay 10 1)
10

* (= (gross-pay 50 1)
     (+ (* 40 1) 
        (* 10 3/2)))
T

Input/output

如果需要，您可以将逻辑包装在命令行界面中：

(defun gross-pay/io ()
  (gross-pay
   (ask "Enter working hours: " '(integer 0 60))
   (ask "Enter hourly pay rate: " '(integer 1 1000))))

以上工作得益于此辅助函数，它处理请求输入时可能出现的不同问题（清除缓冲、强制输出、读取值时禁用评估、检查类型等）

(defun ask (prompt type)
  (let ((*standard-output* *query-io*))
    (loop
      (clear-input)
      (fresh-line)
      (princ prompt)
      (finish-output)
      (let ((value (let ((*read-eval* nil)) (read))))
        (if (typep value type)
            (return value)
            (format *error-output*
                    "type mismatch: ~a not of type ~a"
                    value type))))))

在我的环境中，这是一个交互示例：

USER> (gross-pay/io)

Enter working hours: 5

Enter hourly pay rate: 3

15

以及错误输入的示例：

Enter working hours: 87
type mismatch: 87 not of type (INTEGER 0 60)
Enter working hours: ""
type mismatch:  not of type (INTEGER 0 60)
Enter working hours: 15

Enter hourly pay rate: 0
type mismatch: 0 not of type (INTEGER 1 1000)
Enter hourly pay rate: 88

1320

试图计算总工资

Trying to compute gross pay

lisp

clisp

common-lisp

业务逻辑

测试

Input/output