Google 工作表一次性使用日期和类别过滤器

Question

我正在尝试对 google 工作表中的值求和。我想要每月概览和每个类别的总和。

我的数据具有这些特征：

 date, category, value
 01-01-2021, blue, 50
 02-01-2021, green, 100
 01-02-2021, blue 50
 15-01-2021, orange, 30
 12-02-2021, orange, 50
 18-01-2021, blue, 20

我想分组如下：

 month, category, value
 January, blue, 70
 January, orange, 30
 February, blue, 50
 February, green, 100
 February, orange, 50

我设法对特定日期之间的值求和。因此，如上例所示组合日期和值列。现在我想给它添加类别。

我的函数：

=SUMIFS(F2:F362;B2:B362;">="&D3;B2:B362 ;"<="&D4)

F2:F362为取值范围 B2:B362 是日期范围 D3 = 最小日期 D4 = 最大日期

如有任何帮助或提示，我们将不胜感激！不确定我是否应该继续执行此功能或在其周围添加一些内容。在当前问题中找不到此组合挑战，只能找到单独的挑战。

Answer 1

尝试：

=QUERY(A1:C, 
 "select month(A)+1,sum(C) 
  where A is not null 
  group by month(A)+1 
  pivot B
  label month(A)+1'month'", 1)

或反向分布：

=QUERY(A1:C, 
 "select B,sum(C) 
  where A is not null 
  group by B 
  pivot month(A)+1", 1)

添加外部日期边界：

=QUERY(A1:C, 
 "select B,sum(C) 
  where A >= date '"&TEXT(D3, "yyy-mm-dd")&"'
    and A <= date '"&TEXT(D4, "yyy-mm-dd")&"'
  group by B 
  pivot month(A)+1", 1)

Google 工作表一次性使用日期和类别过滤器

Google sheets use a filter on date and category in one go

filter

google-sheets

google-query-language

google-sheets-formula