尽管没有错误，但芝麻存储库未使用 INSERT 进行更新

Question

我正在尝试使用来自 dbpedia 的数据更新 Sesame 存储库。我有以下查询：

PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX : <http://dbpedia.org/resource/>
PREFIX dbpedia2: <http://dbpedia.org/property/>
PREFIX dbpedia: <http://dbpedia.org/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

INSERT{?s ?p ?o}

WHERE {
 SERVICE <http://dbpedia.org/sparql>{

{:Rotavirus_vaccine ?p ?o.
}
UNION
{
?s ?p :Rotavirus_vaccine.
}
}
}

此查询没有显示任何错误，也没有更新存储库。另一方面，将 UNION 拆分为两个单独的查询，然后一个一个地更新存储库。为什么查询单独工作而不是联合工作？单个查询代码为：

INSERT{:Rotavirus_vaccine ?p ?o}        
WHERE {
SERVICE <http://dbpedia.org/sparql>{
{:Rotavirus_vaccine ?p ?o.
}
}
}

Answer 1

?s ?p ?o 必须全部定义在一行中，模板才有意义。任何时候未绑定变量，都不会进行更新。

在 UNION 的一个分支中，定义了 ?s ?p，在另一个分支中定义了 ?p ?o。所以所有3个都没有在同一行中定义。

为第一部分添加 BIND 或 FILTER 例如：

{:Rotavirus_vaccine ?p ?o. BIND(:Rotavirus_vaccine AS ?s) }

{?s ?p ?o. FILTER(?s = :Rotavirus_vaccine }

或使用这个

INSERT{:Rotavirus_vaccine ?p ?o.
       ?s ?p :Rotavirus_vaccine.
}

因为每个案例都定义了其中一个。

Answer 2

我已经能够通过对 UNION 的两个子句使用 BIND 来执行功能查询。代码是：

INSERT{?s ?p ?o} 
WHERE 
{ 
SERVICE <dbpedia.org/sparql>
{ 
{:Rotavirus_vaccine ?p ?o. BIND(:Rotavirus_vaccine AS ?s)} 
UNION {?s ?p :Rotavirus_vaccine. BIND(:Rotavirus_vaccine AS ?o) } 
} 
}

尽管没有错误，但芝麻存储库未使用 INSERT 进行更新

Sesame repository not being updated using INSERT despite no error

sparql

semantic-web

sesame

linked-data