如何使 zsh 函数从单词中间自动完成？

Question

我使用 zsh 并编写了一个函数来替换 cd 函数。在一些帮助下，我让它像我希望的那样工作（大部分）。这是的后续。该功能几乎按我想要的方式工作，但我在语法高亮和自动完成方面仍然存在一些问题。

对于示例，假设您的目录如下所示：

/
    a/
        b/
        c/
            d/
        some_dir/

我还假设已获取以下代码：

cl () {
    local first=$( echo  | cut -d/ -f1 )
    if [ -d $first ]; then
        pushd  >/dev/null # If the first argument is an existing normal directory, move there
    else
        pushd ${PWD%/$first/*}/ >/dev/null # Otherwise, move to a parent directory or a child of that parent directory
    fi
}
_cl() {
    _cd
    pth=${words[2]}
    opts=""
    new=${pth##*/}
    local expl
    # Generate the visual formatting and store it in `$expl`
    _description -V ancestor-directories expl 'ancestor directories'
    [[ "$pth" != *"/"*"/"* ]] && middle="" || middle="${${pth%/*}#*/}/"
    if [[ "$pth" != *"/"* ]]; then
        # If this is the start of the path
        # In this case we should also show the parent directories
        local ancestor=$PWD:h
        while (( $#ancestor > 1 )); do
            # -f: Treat this as a file (incl. dirs), so you get proper highlighting.
            # -Q: Don't quote (escape) any of the characters.
            # -W: Specify the parent of the dir we're adding.
            # ${ancestor:h}: The parent ("head") of $ancestor.
            # ${ancestor:t}: The short name ("tail") of $ancestor.
            compadd "$expl[@]" -fQ -W "${ancestor:h}/" - "${ancestor:t}"
            # Move on to the next parent.
            ancestor=$ancestor:h
        done
    else
        # $first is the first part of the path the user typed in.
        # it it is part of the current direoctory, we know the user is trying to go back to a directory
        first=${pth%%/*}
        # $middle is the rest of the provided path
        if [ ! -d $first ]; then
            # path starts with parent directory
            dir=${PWD%/$first/*}/$first
            first=$first/
            # List all sub directories of the $dir/$middle directory
            if [ -d "$dir/$middle" ]; then
                for d in $(ls -a $dir/$middle); do
                    if [ -d $dir/$middle/$d ] && [[ "$d" != "." ]] && [[ "$d" != ".." ]]; then
                        compadd "$expl[@]" -fQ -W $dir/ - $first$middle$d
                    fi
                done
            fi
        fi
    fi
}
compdef _cl cl

问题：

在我的 zshrc 中，有一行：

zstyle ':completion:*' matcher-list 'm:{a-z}={A-Za-z}' '+l:|=* r:|=*'

这应该使自动完成不区分大小写，并确保我可以开始输入目录名称的最后一部分，并且仍然会完成全名

示例：

$ cd /a
$ cd di[tab] # replaces 'di' with 'some_dir/'
$ cl di[tab] # this does not do anything. I would like it to replace 'di' with 'some_dir'

如何让它在我输入 'di' 时提示 'some_dir'？

Answer 1

你的 matcher-list 中的第二个匹配器永远不会被调用，因为 _cl() return 的“真”（实际上是退出状态 0）即使它没有添加任何匹配项。返回“true”会导致 _main_complete() 假设我们已经完成，因此它不会尝试列表中的下一个匹配器。

要解决此问题，请将以下内容添加到 _cl() 的开头：

local -i nmatches=$compstate[nmatches]

到 _cl() 结尾：

(( compstate[nmatches] > nmatches ))

这样，_cl() 只有在成功添加完成后才会 return “真”。

如何使 zsh 函数从单词中间自动完成？

How do I make a zsh function autocomplet from the middle of a word?

autocomplete

zsh

tab-completion

zsh-completion