Google 工作表 - 消除两个范围内的共同元素

Question

我正在尝试为我正在做的项目制作一个分配系统。我有两个 google 表单链接到我的电子表格，因此我有三个单独的工作表：Start、Finish 和 Sheet1。 Sheet1 是我希望显示活动分配的位置，Start 和 Finish 是 google 表单结果的位置。每个分配都有三列：用户名、项目和数量。某人开始的任务的细节在开始中，某人完成的任务的细节在完成中列出。

假设我在“开始”中有以下数据：

Username	Item	Quantity
12345	Apple	3
12345	Apple	3
54321	Orange	2
12345	Orange	4

Finish 中的数据如下：

Username	Item	Quantity
12345	Apple	3
12345	Orange	4

然后，我希望 Sheet1 显示以下内容：

Username	Item	Quantity
12345	Apple	3
54321	Orange	2

基本上，它需要成对的匹配行并消除它们。然后，它将保留在 Start 中的所有内容并显示在 Sheet1 中。我可以在 Sheet1 中放入可以执行此操作的函数吗？

Answer 1

尝试：

=INDEX(ARRAY_CONSTRAIN(SPLIT(FILTER(
          A3:A&"×"&B3:B&"×"&C3:C&"×"&
 COUNTIFS(A3:A&"×"&B3:B&"×"&C3:C, 
          A3:A&"×"&B3:B&"×"&C3:C, ROW(A3:A), "<="&ROW(A3:A)), NOT(COUNTIF(
          E3:E&"×"&F3:F&"×"&G3:G&"×"&
 COUNTIFS(E3:E&"×"&F3:F&"×"&G3:G, 
          E3:E&"×"&F3:F&"×"&G3:G, ROW(E3:E), "<="&ROW(E3:E)),
          A3:A&"×"&B3:B&"×"&C3:C&"×"&
 COUNTIFS(A3:A&"×"&B3:B&"×"&C3:C, 
          A3:A&"×"&B3:B&"×"&C3:C, ROW(A3:A), "<="&ROW(A3:A))))), "×"), 9^9, 3))

Google 工作表 - 消除两个范围内的共同元素

Google sheets - eliminating common elements from two ranges

arrays

filter

countif

google-sheets

google-sheets-formula