查询函数无法使用数组数据范围引用

Question

目标：

我想优化查询功能的数据处理速度，实际上可以正常运行，但有时会非常慢（1-2分钟）。所以我正在改进我的整个 sheet。我提到了这个：https://webapps.stackexchange.com/questions/106809/how-can-i-speed-up-google-sheets

话虽如此，我认为我可以通过将数据范围从常规引用更改为数组范围引用来改进下面的查询设置。

当前查询的工作原理：

下面的截图是一个查询函数，它从 sheet 中提取数据（混合数据，它也从另一个 sheet 中提取数据）并计算状态数（技术问题，咨询中，进行中和需要信息）每个人（代理人）。

这是我的查询函数。

=QUERY(
    'Blend Data'!$A:$C,
    "select C, COUNT(C) where B matches 
    'In Progress|In Consult|Need Info|Technical Issue'
    AND C matches'"
    &IFERROR(VLOOKUP(Values!F2,Values!F2:F,1,FALSE))&"|"
    &IFERROR(VLOOKUP(Values!F3,Values!F2:F,1,FALSE))&"|"
    &IFERROR(VLOOKUP(Values!F4,Values!F2:F,1,FALSE))&"|"
    &IFERROR(VLOOKUP(Values!F5,Values!F2:F,1,FALSE))&"|"
    &IFERROR(VLOOKUP(Values!F6,Values!F2:F,1,FALSE))&"'
    GROUP BY C pivot B",
    1)

有关查询设置的详细信息：

混合数据：是同一个传播sheet中的一个sheet，它从同一传播sheet中的2个sheet中提取数据sheet，其中包括代理和票务信息。
VLOOKUP: "Values!F2" 正在从同一传播sheet 中的单独 sheet 中提取代理名称。我想使用参考而不是硬编码，因为名称有时会改变。

有关“混合数据 sheet”的更多信息：

混合数据 sheet 正在使用查询函数拉取 2 个单独的 sheets（“Sheet 数据” sheet 从不同的 Spreadsheet, "Sheet B Data" sheet 从不同的 Spreadsheet) 中提取数据，我能够使用 Importrange 函数做到这一点。这是屏幕截图。

这是我的查询函数。

=QUERY(
    {
        IMPORTRANGE("1DeXTU7dJVJFYIHSP8U9dsKw3YNZVtEZIjbURAd54Xjs","'Sheet A Data'!$A:$H");
        IMPORTRANGE("1QUZ-ljkXNOvtnPg-a2FqM2PhYUdt_zX5gMLtB6GcFdc","'Sheet B Data'!$A:$H")
    },
    A1,
    1
)

问题：

如上所说，我想把数据改成数组格式；但是，我收到一个错误（无法解析函数查询参数 2 的查询字符串：NO_COLUMN: C）。

这是我尝试做的事情。

=QUERY(
    {
        IMPORTRANGE("1DeXTU7dJVJFYIHSP8U9dsKw3YNZVtEZIjbURAd54Xjs","'Sheet A Data'!$A:$H");
        IMPORTRANGE("1QUZ-ljkXNOvtnPg-a2FqM2PhYUdt_zX5gMLtB6GcFdc","'Sheet B Data'!$A:$H")
    },
    "select C, COUNT(C) where B matches 'In Progress|In Consult|Need Info|Blocked By' AND C matches '"
    &IFERROR(VLOOKUP(Values!F2,Values!F2:F,1,FALSE))&"|"
    &IFERROR(VLOOKUP(Values!F3,Values!F2:F,1,FALSE))&"|"
    &IFERROR(VLOOKUP(Values!F4,Values!F2:F,1,FALSE))&"|"
    &IFERROR(VLOOKUP(Values!F5,Values!F2:F,1,FALSE))&"|"
    &IFERROR(VLOOKUP(Values!F6,Values!F2:F,1,FALSE))&"'
    GROUP BY C pivot B",
  1
)

Answer 1

当您使用构造范围 {} 时，您不能在查询中使用 A,B,C 引用。相反，您需要使用 Col1,Col2,Col3 符号

=QUERY({
 IMPORTRANGE("1DeXTU7dJVJFYIHSP8U9dsKw3YNZVtEZIjbURAd54Xjs", "Sheet A Data!A3:H");
 IMPORTRANGE("1QUZ-ljkXNOvtnPg-a2FqM2PhYUdt_zX5gMLtB6GcFdc", "Sheet B Data!A3:H")},
 "select Col3,count(Col3) 
  where Col2 matches 'In Progress|In Consult|Need Info|Blocked By' 
    and Col3 matches '"
  &IFERROR(VLOOKUP(Values!F2, Values!F2:F, 1, 0))&"|"
  &IFERROR(VLOOKUP(Values!F3, Values!F2:F, 1, 0))&"|"
  &IFERROR(VLOOKUP(Values!F4, Values!F2:F, 1, 0))&"|"
  &IFERROR(VLOOKUP(Values!F5, Values!F2:F, 1, 0))&"|"
  &IFERROR(VLOOKUP(Values!F6, Values!F2:F, 1, 0))&"'
  group by Col3 
  pivot Col2", 1)

查询函数无法使用数组数据范围引用

Query function unable to use array data range reference

arrays

pivot

google-sheets

google-query-language

google-sheets-formula

目标：

当前查询的工作原理：

有关查询设置的详细信息：

有关“混合数据 sheet”的更多信息：

问题：