在 google sheet 中添加 2 个迷你图以创建新的迷你图

Question

我有 2 个迷你图。两者都是根据一年前到今天的股票历史股价创建的。我想创建一个新的迷你图，它是这两个图表的总和。这是否可能，因为它们具有相同数量的数据点，即 365。例如

=SPARKLINE(GOOGLEFINANCE("AMZN","price",TODAY()-365,TODAY(),"daily"),{"charttype","line";"linewidth",1;"color","#5f88cc"})
=SPARKLINE(GOOGLEFINANCE("MSFT","price",TODAY()-365,TODAY(),"daily"),{"charttype","line";"linewidth",1;"color","#5f88cc"})

Answer 1

您可以将它们连接为一个数组，然后使用查询来添加它们：

=SPARKLINE(
  QUERY(
    {
      GOOGLEFINANCE("AMZN","price",TODAY()-365,TODAY(),"daily"),
      GOOGLEFINANCE("MSFT","price",TODAY()-365,TODAY(),"daily")
    },
    "select Col1, Col2+Col4",
    1
  )
)

破败

我们首先加入两个数组。为此，我们使用数组语法 {A,B} 逐行连接它们，形成一个 4 列数组：

={
  GOOGLEFINANCE("AMZN","price",TODAY()-365,TODAY(),"daily"),
  GOOGLEFINANCE("MSFT","price",TODAY()-365,TODAY(),"daily")
}

现在我们可以应用查询来获取我们想要的值：

=QUERY(
  {
    GOOGLEFINANCE("AMZN","price",TODAY()-365,TODAY(),"daily"),
    GOOGLEFINANCE("MSFT","price",TODAY()-365,TODAY(),"daily")
  },
  "select Col1, Col2+Col4",
  1
)

查询生成了 2 行：

日期列。由于两者应该相同，因此无需更改任何内容
2 Close 列（2 和 4）的总和

之后我们可以简单地将所有内容包装到 SPARKLINE 函数中，我们就得到了最终结果。

如果您不喜欢空白字符，可以毫无问题地删除它们。

在 google sheet 中添加 2 个迷你图以创建新的迷你图

Add 2 sparlines in a google sheet to create a new sparkline

google-sheets

sparklines

破败

参考