编辑数组的维度 vba

Question

我有一个这样的数组

dim arr(1 to 5) as string

arr(1)="a"
arr(3)="b"
arr(5) = "c"

（arr(2),arr(4) 为空）。

如何重新调整此 arr(1to5) 以排除空值并同时保存值“a”、“b”、“c”（我希望输出像 arr(1to3), arr(1)="a", arr(2)="b", arr(3)="c"）？一般来说，我不知道其中有多少是空的，所以我需要一些通用代码（不是针对这个特定示例）。

我正在考虑新的临时数组来保存所有非空值，然后重新调整 arr(1to5)。

也许这是更好（更快）的方法？

I wrote sth similar:
Sub test()
Dim myArray() As String
Dim i As Long
Dim y As Long


ReDim Preserve myArray(3)
myArray(1) = "a"
myArray(3) = "c"

Dim myArray2() As String
y = 1
For i = LBound(myArray) To UBound(myArray)

If myArray(i) <> "" Then

ReDim Preserve myArray2(y)
myArray2(y) = myArray(i)
y = y + 1

End If
Next i

ReDim myArray(UBound(myArray2))
myArray = myArray2

End Sub

但是我想避免创建新数组。

Answer 1

创建一个相同大小的新数组。循环第一个数组并将值不为空时插入新数组，跟踪新数组中最后一个有值的点，然后 redim 将新数组保留为仅具有值的大小。

Sub kjlkj()
    Dim arr(1 To 5) As String
    
    arr(1) = "a"
    arr(3) = "b"
    arr(5) = "c"
    
    Dim newArr() As String
    ReDim newArr(1 To UBound(arr))
    
    Dim j As Long
    j = LBound(newArr)
    
    Dim i As Long
    For i = LBound(arr) To UBound(arr)
        If arr(i) <> "" Then
            newArr(j) = arr(i)
            j = j + 1
        End If
    Next i
    
    ReDim Preserve newArr(LBound(newArr) To j - 1)

    'do what you want with the new array.
    
    
End Sub

Answer 2

替代方法 Filter() 函数

"However I would like to avoid creating new array."

负面过滤允许一个基本上简单的替代方案，但是你必须

动态声明您的数组（即没有预设数量的元素）以允许重建覆盖原始数组，
对连接的数组元素执行双重替换，以允许插入可过滤掉的唯一字符。

Sub testFilter()
    Dim arr() As String                                     
    ReDim arr(1 To 5)
    arr(1) = "a"
    arr(3) = "b"
    arr(5) = "c"
    'Debug.Print Join(arr, ",")                             ' ~~> a,,b,,c     

    'rearrange arr via RemoveEmpty()
    arr = RemoveEmpty(arr)                                  ' >>  function RemoveEmpty()
    Debug.Print Join(arr, ",")                              ' ~~> a,b,c

End Sub

帮助函数RemoveEmpty()

添加未使用的唯一字符，例如$，对空元素加上最终的负过滤允许去除这些被标记的元素。

注意双重替换是必要的，以允许通过 $ 标记标记连续的 empty 元素，如 VBA 会在这里跳过其他字符。

Function RemoveEmpty(arr)
    Dim tmp
    tmp = Replace(Replace(Join(arr, "|"), "||", "|$|"), "||", "|$|")
    RemoveEmpty = Filter(Split(tmp, "|"), "$", False)
End Function

编辑数组的维度 vba

edit dimension of array vba

arrays

vba

dimensions