使用 scons 构建 dll 时，如何修复未解析的外部符号 _DllMainCRTStartup？

Question

编辑：原来是用户错误。我的资源不在 NativeLib/，它在 NativeLib/NativeLib/。经常检查你的路径！

我正在尝试使用 visual studio community 2019 和 scons 4.1.0 构建一个 dll，但我得到了一个未解析的外部符号。

E:\Projects\GodotProjects\Units\Units>scons -c platform=windows
scons: Reading SConscript files ...
scons: done reading SConscript files.
scons: Cleaning targets ...
scons: done cleaning targets.

E:\Projects\GodotProjects\Units\Units>scons platform=windows
scons: Reading SConscript files ...
scons: done reading SConscript files.
scons: Building targets ...
link /nologo /dll /out:Godot\bin\win64\libgdexample.dll /implib:Godot\bin\win64\libgdexample.lib /LIBPATH:E:\Projects\GodotProjects\Units\godot-cpp\bin libgodot-cpp.windows.debug.64.lib
LINK : warning LNK4001: no object files specified; libraries used
LINK : warning LNK4068: /MACHINE not specified; defaulting to X64
LINK : error LNK2001: unresolved external symbol _DllMainCRTStartup
Godot\bin\win64\libgdexample.dll : fatal error LNK1120: 1 unresolved externals
scons: *** [Godot\bin\win64\libgdexample.dll] Error 1120
scons: building terminated because of errors.

根据文档 (DLLs and Visual C++ run-time library behavior)，“当您使用 Visual Studio 构建动态-link 库 (DLL) 时，默认情况下，link er 包括 Visual C++ 运行-time 库 (VCRuntime)。...当 linked 到 DLL 中时，VCRuntime 代码提供一个名为 _DllMainCRTStartup 的内部 DLL 入口函数，它处理 Windows OS 消息到 DLL 以附加到进程或线程或从进程或线程分离。"

所以听起来我需要以某种方式包含 VCRuntime，但我找不到它的库。根据 this，_DllMainCRTStartup 在 corelibc.lib 中，但我找不到任何关于在哪里找到它或如何包含它的信息。

我也不知道对 _DllMainCRTStartup 的引用在哪里。它不在我的任何 .cpp 或 .h 文件中，我无法在 sconstruct 文件或任何 visual studio 文件中找到它。我认为我对编译器的了解还不足以进一步调试它。

这是我的 SConstruct 文件：

#!python
import os, subprocess

opts = Variables([], ARGUMENTS)

# Gets the standard flags CC, CCX, etc.

# env = DefaultEnvironment()    - changed at request of bdbaddog
env = Environment()

# Define our options
opts.Add(EnumVariable('target', "Compilation target", 'debug', ['d', 'debug', 'r', 'release']))
opts.Add(EnumVariable('platform', "Compilation platform", '', ['', 'windows', 'x11', 'linux', 'osx']))
opts.Add(EnumVariable('p', "Compilation target, alias for 'platform'", '', ['', 'windows', 'x11', 'linux', 'osx']))
opts.Add(BoolVariable('use_llvm', "Use the LLVM / Clang compiler", 'no'))
opts.Add(PathVariable('target_path', 'The path where the lib is installed.', 'Godot/bin/'))
opts.Add(PathVariable('target_name', 'The library name.', 'libgdexample', PathVariable.PathAccept))

# Local dependency paths, adapt them to your setup
godot_headers_path = "../godot-cpp/godot-headers/"
cpp_bindings_path = "../godot-cpp/"
cpp_library = "libgodot-cpp"

# only support 64 at this time..
bits = 64

# Updates the environment with the option variables.
opts.Update(env)

# Process some arguments
if env['use_llvm']:
    env['CC'] = 'clang'
    env['CXX'] = 'clang++'

if env['p'] != '':
    env['platform'] = env['p']

if env['platform'] == '':
    print("No valid target platform selected.")
    quit();

# Check our platform specifics
if env['platform'] == "osx":
    env['target_path'] += 'osx/'
    cpp_library += '.osx'
    if env['target'] in ('debug', 'd'):
        env.Append(CCFLAGS = ['-g','-O2', '-arch', 'x86_64', '-std=c++17'])
        env.Append(LINKFLAGS = ['-arch', 'x86_64'])
    else:
        env.Append(CCFLAGS = ['-g','-O3', '-arch', 'x86_64', '-std=c++17'])
        env.Append(LINKFLAGS = ['-arch', 'x86_64'])

elif env['platform'] in ('x11', 'linux'):
    env['target_path'] += 'x11/'
    cpp_library += '.linux'
    if env['target'] in ('debug', 'd'):
        env.Append(CCFLAGS = ['-fPIC', '-g3','-Og', '-std=c++17'])
    else:
        env.Append(CCFLAGS = ['-fPIC', '-g','-O3', '-std=c++17'])

elif env['platform'] == "windows":
    env['target_path'] += 'win64/'
    cpp_library += '.windows'
    # This makes sure to keep the session environment variables on windows,
    # that way you can run scons in a vs 2017 prompt and it will find all the required tools
    # env.Append(ENV = os.environ)

    #env.Append(CCFLAGS = ['-DWIN32', '-D_WIN32', '-D_WINDOWS', '-W3', '-GR', '-D_CRT_SECURE_NO_WARNINGS'])    - changed at request of bdbaddog
    env.Append(CCFLAGS = ['-D_WIN32', '-D_WINDOWS', '-W3', '-GR', '-D_CRT_SECURE_NO_WARNINGS'])
    env.Append(CPPDEFINES = ['WIN32'])
    
    if env['target'] in ('debug', 'd'):
        env.Append(CCFLAGS = ['-EHsc', '-D_DEBUG', '-MDd'])
    else:
        env.Append(CCFLAGS = ['-O2', '-EHsc', '-DNDEBUG', '-MD'])

if env['target'] in ('debug', 'd'):
    cpp_library += '.debug'
else:
    cpp_library += '.release'

cpp_library += '.' + str(bits)

# make sure our binding library is properly includes
env.Append(CPPPATH=['.', godot_headers_path, cpp_bindings_path + 'include/', cpp_bindings_path + 'include/core/', cpp_bindings_path + 'include/gen/'])
env.Append(LIBPATH=[cpp_bindings_path + 'bin/'])
env.Append(LIBS=[cpp_library])

# tweak this if you want to use different folders, or more folders, to store your source code in.
env.Append(CPPPATH=['NativeLib/'])
sources = Glob('NativeLib/*.cpp')

library = env.SharedLibrary(target=env['target_path'] + env['target_name'] , source=sources)

Default(library)

# Generates help for the -h scons option.
Help(opts.GenerateHelpText(env))

Answer 1

来自这一行

link /nologo /dll /out:Godot\bin\win64\libgdexample.dll /implib:Godot\bin\win64\libgdexample.lib /LIBPATH:E:\Projects\GodotProjects\Units\godot-cpp\bin libgodot-cpp.windows.debug.64.lib

我发现您仍然没有编译任何源文件。这可能是您真正的问题。

在您的 Glob 资源之后添加此内容

for s in sources:
    print("Source:%s"%s)

运行并更新上面的输出。

使用 scons 构建 dll 时，如何修复未解析的外部符号 _DllMainCRTStartup？

How can I fix an unresolved external symbol _DllMainCRTStartup when building a dll with scons?

c++

scons

visual-studio