通过替换合并 SAS 中的两个不相等的数据集

Question

我在 SAS 中生成了倾向得分，以通过替换来匹配两个不相等的组。现在我正在尝试创建一个数据集，其中两个组的观察值数量相等——即 b 组中应该有重复的观察值，因为这是较小的组。下面我有综合数据来证明我想要得到什么。

Indicator Income  Matchid
1         7       1
1         8       2
1         4       1
0         6       1
0         9       2

我希望它看起来像这样

Indicator Income  Matchid
1         7       1
1         8       2
1         4       1
0         6       1
0         9       2
0         6       1

Answer 1

在视图中，您可以创建一个变量，它是一个适合模数计算的组序号。在数据步骤中，将两个指标组加载到单独的哈希中，然后针对最大组大小的每个循环，按索引模数组大小进行选择。

示例：

data have;
input Indicator Income  Matchid;
datalines;
1         7       1
1         8       2
1         4       1
0         6       1
0         9       2
;

data have_v;
  set have;
  by indicator notsorted;
  if first.indicator then group_seq=0; else group_seq+1;
run;


data want;
  if 0 then set have_v;

  declare hash i1 (dataset:'have_v(where=(indicator=1))', ordered:'a');
  i1.defineKey('group_seq');
  i1.defineData(all:'yes');
  i1.defineDone();

  declare hash i0 (dataset:'have_v(where=(indicator=0))', ordered:'a');
  i0.defineKey('group_seq');
  i0.defineData(all:'yes');
  i0.defineDone();

  do index = 0 to max(i0.num_items, i1.num_items)-1;
    group_seq = mod(index,i1.num_items);
    i1.find();
    output;
  end;

  do index = 0 to max(i0.num_items, i1.num_items)-1;
    group_seq = mod(index,i0.num_items);
    i0.find();
    output;
  end;

  stop;

  drop index group_seq;
run;

如果两组被分成数据集，您可以使用 SET 选项 nobs= 和 point=

进行类似的处理

通过替换合并 SAS 中的两个不相等的数据集

Merge two unequal data sets in SAS with replacment

merge

sas

propensity-score-matching