在 Delphi XE 中在运行时设置 onclick 事件

Question

先post到这里，如有礼仪失误，敬请见谅。

我正在 Delphi XE8 中创建一个多设备 (FMX) 应用程序，但很难将事件处理程序分配给动态创建的按钮。我搜索了 Whosebug 并找到了与 NotifyEvents 相关的答案，所以我遵循了这些答案中的建议 - 仍然没有运气。编译错误为"E2010 Incompatible types: 'TNotifyEvent' and 'Procedure'".

我整理了一个简单的表单测试用例，其中包含一个编辑字段和一个静态 Hello 按钮，第二个按钮创建一个 Goodbye 按钮并尝试为 OnClick 事件分配一个过程，但我仍然得到同样的错误。

据我所知，我已经遵循了使过程与 TNotifyEvent 兼容的所有要求，但即使是这个基本示例也会因同样的错误而失败。我正在用头撞墙所以有人可以让我知道我做错了什么吗？

非常感谢。

unit Dynamic_Button_Test1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.StdCtrls,
  FMX.Controls.Presentation, FMX.Edit;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Hello: TButton;
    Create_GoodBye: TButton;
    procedure HelloClick(Sender: TObject);
    procedure Create_GoodByeClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    procedure GoodbyeClick(Sender: TObject) ;
  end;

var
  Form1: TForm1;

implementation

{$R *.fmx}

procedure TForm1.Create_GoodByeClick(Sender: TObject);
var
  New_Button : TButton ;
begin
New_Button := TButton.Create( Form1 );
New_Button.Parent := Form1 ;
New_Button.Text := 'Goodbye' ;
New_Button.Visible := True ;
New_Button.Margins.Left := 50 ;
New_Button.Margins.Right := 50 ;
New_Button.Margins.Bottom := 30 ;
New_Button.Height := 50 ;
New_Button.Align := TAlignLayout.Bottom ;

New_Button.OnClick := TForm1.GoodbyeClick ;
end;

procedure TForm1.HelloClick(Sender: TObject);
begin
Edit1.Text := 'Hello' ;
end;

procedure TForm1.GoodbyeClick(Sender: TObject);
begin
Edit1.Text := 'Goodbye' ;
end;

end.

Answer 1

VCL/FMX 事件处理程序在运行时绑定到特定对象。分配事件处理程序时，需要用对象指针替换 class 类型名。当稍后触发事件时，该对象将成为事件处理程序的 Self 指针：

New_Button.OnClick := Self.GoodbyeClick ;

或者简单地说：

New_Button.OnClick := GoodbyeClick ; // Self implicitly used

附带说明 - 创建按钮时，该代码位于 TForm1 实例方法中，因此您应该使用 Self 对象指针而不是全局 Form1 对象指针：

New_Button := TButton.Create( Self );
New_Button.Parent := Self ;

在 Delphi XE 中在运行时设置 onclick 事件

Set onclick event at runtime in Delphi XE

delphi

event-handling

firemonkey