如何验证多个用户窗体文本框？

Question

我有一个包含用户表单的工作簿，可以写入多个数字和日期字段。我需要验证文本框控件的正确数字和日期。

与其复制每个文本框的验证，不如在每个文本框的 BeforeUpdae 事件中调用一个公共子过程。

我有两个问题。

如果我执行表单并使用 tbAmount 框中的文本进行测试，似乎未调用 ContolValidate 过程。
如果我运行它处于断点模式并在 Call ContolValidate(What, CurrentControl) 上设置断点，它将逐步执行该过程。
即使它逐步完成了整个过程，Cancel = True 似乎也不起作用。
如果我将 ContolValidate 代码直接粘贴到 BeforeUpdate 中，Cancel = True 确实有效。

此代码全部在用户表单上。

Private Sub tbAmount1_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
    Dim What As String
    Dim CurrentControl As Control

    What = "NumericField"
    Set CurrentControl = Me.ActiveControl
    Call ContolValidate(What, CurrentControl)
End Sub

Private Sub ContolValidate(What, CurrentControl)
    If Not IsNumeric(CurrentControl.Value) Then
        ErrorLabel.Caption = "Please correct this entry to be numeric."
        Cancel = True
        CurrentControl.BackColor = rgbPink
        CurrentControl.SelStart = 0
        CurrentControl.SelLength = Len(CurrentControl.Value)
    Else
        If CurrentControl.Value < 0 Then
            ErrorLabel.Caption = "This number cannot be negative."
            Cancel = True
            CurrentControl.BackColor = rgbPink
            CurrentControl.SelStart = 0
            CurrentControl.SelLength = Len(CurrentControl.Value)
        End If
    End If
End Sub

Private Sub tbAmount1_AfterUpdate()
    ErrorLabel.Visible = False
    tbAmount1.BackColor = Me.BackColor
End Sub

Answer 1

(1) 当您的控件被命名为 tbAmount1 并且代码在表单的代码隐藏模块中时，触发器应该触发。

(2) 正如@shahkalpesh 在他的评论中提到的，Cancel 在您的验证程序中是未知的。将 Option Explicit 放在代码的顶部会告诉你这一点。
我建议将例程转换为函数。在下面的代码中，我 return True 如果内容没问题， False 如果不正确（所以你需要在结果中添加 Not 来设置 Cancel-参数)

Private Sub tbAmount1_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
    Cancel = Not ControlValidate("NumericField", Me.ActiveControl)
End Sub

Private Function ControlValidate(What, CurrentControl) As Boolean
    ControlValidate = False

    If Not IsNumeric(CurrentControl.Value) Then
        errorlabel.Caption = "Please correct this entry to be numeric."
    ElseIf CurrentControl.Value < 0 Then
        errorlabel.Caption = "This number cannot be negative."
    Else
        ControlValidate = True   ' Input is okay.
    End If
    
    If ControlValidate Then
        CurrentControl.BackColor = vbWhite
    Else
        CurrentControl.BackColor = rgbPink
        CurrentControl.SelStart = 0
        CurrentControl.SelLength = Len(CurrentControl.Value)
    End If
End Function

P.S.: 我将名称更改为 ControlValidate - “contol” 对我来说似乎是错误的...

如何验证多个用户窗体文本框？

How to validate several userform textboxes?

excel

vba

userform