方案：使用open-i/o-file函数

Question

我正在使用 MIT Scheme 10.1.5，我很好奇为什么使用 open-i/o-file 的以下代码无法正常工作。有人知道问题出在哪里吗？

(define l "~/tmp0")
(define x ''(a b (c d) e f))

(let ((p (open-i/o-file l)))
  (begin (write x p)
     (flush-output p)
     (let ((r (read p)))
       (close-port p)
       r)))
;Value: #!eof

当我期待时：

;Value: (quote (a b (c d) e f))

当使用 open-input-file 或 open-output-file 时，预期结果：

(let ((p (open-output-file l)))
  (write x p)
  (close-port p))

(let ((p (open-input-file l)))
  (let ((r (read p)))
    (close-port p)
    r))
;Value: (quote (a b (c d) e f))

Answer 1

当您读取或写入端口时，端口位置会提前。写入i/o端口后，如果要读取写入的内容，需要重新设置端口的位置。

这在 MIT/GNU 方案参考手册中似乎没有很好的记录，但您可以使用 textual-port-operation 在文本端口上执行操作。现在，由于几个原因，这比您想要的要复杂一些。

首先，textual-port-operation接受一个端口和一个符号作为它的参数，return是一个完成操作的过程，即textual-port-operation本身不做操作。

其次，textual-port-operation 的符号参数表示操作，但参考手册中没有这些符号的完整列表（据我所知）。您需要在端口上调用 textual-port-operation-names 以了解端口支持哪些操作。

这是 OP 代码的重写版本，其行为符合预期：

(define l "./test-file.dat")
(define x ''(a b (c d) e f))

;; (define (display-port-ops p)
;;   (newline)
;;   (display (textual-port-operation-names p)) (newline)
;;   (newline))

(let* ((p (open-i/o-file l))
       (start ((textual-port-operation p 'position) p)))
  ;; (display-port-ops p)
  (write x p)
  (flush-output p)
  ((textual-port-operation p 'set-position!) p start)
  (let ((r (read p)))
    (close-port p) r))

此处，display-port-ops 程序用于查询端口并发现支持哪些操作以及哪些符号代表这些操作。这必须使用端口参数调用，因此它被放置在 let* 形式中。在将任一调用添加到 textual-port-operation 之前，我调用了它，未注释，以便我可以看到哪些操作可用。 position 和 set-position! 操作看起来很有前途，因此将它们合并到程序中。请注意，let* 必须替换 let，以便 p 的值可以用于计算 start 位置的表达式。

对 display-port-ops 的调用，它只是包装了对 textual-port-operation-names 的调用，显示了这个结果：

(length pathname position set-position! truename write-self close-input eof?
 input-line input-open? input-channel buffered-output-bytes bytes-written
 close-output output-column output-open? output-channel synchronize-output
 char-set close coding known-coding? known-codings known-line-ending?
 known-line-endings line-ending open? set-coding set-line-ending
 supports-coding? char-ready? peek-char read-char read-substring unread-char
 flush-output write-char write-substring)

有了这些程序，下面是发生的事情：

创建端口 p 后，立即调用 (textual-port-operation p 'position)，产生一个将 return 端口位置的过程；此过程在端口 p 上调用，并且 start 绑定到结果，保存端口的初始位置。

写入端口后，调用(textual-port-operation p 'set-position!)，产生一个过程，该过程将改变端口状态，设置新位置；此过程在端口 p 和所需位置 start.

上调用

现在，当在 p 上调用 read 时，从端口的初始位置开始读取。

加载程序时，按预期创建了test-file.dat，REPL中显示了读回文件的结果：

1 (user) => (load "file-io.scm")

;Loading "file-io.scm"... done
;Value: (quote (a b (c d) e f))

方案：使用open-i/o-file函数

Scheme: using open-i/o-file function

io

scheme

file

read-write

mit-scheme