如何在 Haskell 中连接变量参数？

Question

Shell-monad supports variable arguments，但是我找不到一种方法来传递要追加的此类参数列表。可能可以使用该库中存在的函数构造来解决问题，但我想问一下一般问题。

我隐约了解到“varargs”机制是通过函数组合实现的，递归通过使用类型class推断终止。

以该库为例，我想知道是否可以将参数视为“第一个 class”，例如将两个参数分配给一个变量。

这是一个（不正确的）示例，它显示了我的意图。

Prelude Control.Monad.Shell Data.Text> f xs = cmd "cat" xs
Prelude Control.Monad.Shell Data.Text> let a = static ("a" :: Text)
Prelude Control.Monad.Shell Data.Text> let a2 = [a,a]
Prelude Control.Monad.Shell Data.Text> f a2

<interactive>:42:1: error:
    • Could not deduce (Param [Term Static Text])
        arising from a use of ‘f’
      from the context: CmdParams t2
        bound by the inferred type of it :: CmdParams t2 => t2
        at <interactive>:42:1-4
    • In the expression: f a2
      In an equation for ‘it’: it = f a2

Answer 1

没有一点多态递归解决不了的问题：

cmdList :: (Param command, Param arg, CmdParams result) =>
    command -> [arg] -> result
cmdList command = go . reverse where
    go :: (Param arg, CmdParams result) => [arg] -> result
    go [] = cmd command
    go (arg:args) = go args arg

在 ghci 中尝试：

> Data.Text.Lazy.IO.putStr . script $ cmdList "cat" ["dog", "fish"]
#!/bin/sh
cat dog fish

它要求给 cmdList 的所有参数都具有相同的类型，尽管它仍然接受其他类型的附加参数，而不是之后的列表形式。

如果您愿意打开扩展程序，您甚至可以让它接受多个位置的列表，每个位置可能有不同的类型。

list :: (Param arg, CmdParams result) =>
    (forall result'. CmdParams result => result') ->
    [arg] -> result
list f [] = f
list f (arg:args) = list (f arg) args

使用示例：

> T.putStr . script $ list (list (cmd "cat") ["dog", "fish"] "bug") ["turtle", "spider"]
#!/bin/sh
cat dog fish bug turtle spider

前面的cmdList可以定义为cmdList command = list (cmd command)。（N.B。cmdList = list . cmd 不有效！）

接受包含不同类型的列表比较嘈杂，但对于存在类型是可能的。

data Exists c where Exists :: c a => a -> Exists c

elist :: CmdParams result =>
    (forall result. CmdParams result => result) ->
    [Exists Param] -> result
elist f [] = f
elist f (Exists arg:args) = elist (f arg) args

但是看看它用起来有多烦人：

> T.putStr . script $ elist (cmd "cat") [Exists "dog", Exists "fish"]
#!/bin/sh
cat dog fish

前面的list可以通过list f = elist f . map Exists来定义。

如何在 Haskell 中连接变量参数？

How to concatenate variable arguments in Haskell?

haskell

variadic-functions