使用 XSLT 1.0 提取没有不必要名称空间的 XSLT 标记

Question

很遗憾，我是 XLST 的新手。我找不到适合我的问题的解决方案。我必须使用 XSLT 1.0 转换文件。给定文件：

<?xml version="1.0" encoding="UTF-8"?>
<A:A xsi:schemaLocation="urn:A A.xsd" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:A="urn:A">
    <A:B>
        <C xmlns="urn:C">
            <D>foo</D>
        </C>
    </A:B>
    <A:B>
        <C xmlns="urn:C">
            <D>bar</D>
        </C>
    </A:B>
</A:A>

想要的结果：

<?xml version="1.0" encoding="UTF-8"?>
<C xmlns="urn:C">
    <D>foo</D>
</C>
<C xmlns="urn:C">
    <D>bar</D>
</C>

我很难得到想要的结果。我的变压器：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:A="urn:A">

  <xsl:output method="xml" version="1.0" encoding="UTF-8"/>

  <xsl:template match="A:B">
    <xsl:element name="{name()}" namespace="{namespace-uri()}">
      <xsl:copy-of select="node()"/>
    </xsl:element>
  </xsl:template>

</xsl:stylesheet>

生产

<?xml version="1.0" encoding="UTF-8"?>
    <A:B xmlns:A="urn:A">
        <C xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns="urn:C">
            <D>foo</D>
        </C>
    </A:B>
    <A:B xmlns:A="urn:A">
        <C xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns="urn:C">
            <D>bar</D>
        </C>
    </A:B>

关于如何摆脱 A:B 信封的任何想法？

Answer 1

https://xsltfiddle.liberty-development.net/nbiE19Q 处的代码可以

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="/">
      <xsl:apply-templates select="*/*/node()"/>
  </xsl:template>
  
  <xsl:template match="*">
      <xsl:element name="{name()}" namespace="{namespace-uri()}">
          <xsl:apply-templates select="@* | node()"/>
      </xsl:element>
  </xsl:template>

</xsl:stylesheet>

这种方式只处理孙子及其后代的模板，该模板去除了所有名称空间，但每个元素所在的名称空间。

使用 XSLT 1.0 提取没有不必要名称空间的 XSLT 标记

Extract XSLT tags without unnecessary namespaces with XSLT 1.0

xslt

xml-namespaces

xslt-1.0