如何在维基数据中查询最近一天修改过的项目？

Question

我正在尝试检索 latitude/longitude 边界框内 在过去 24 小时内编辑过的所有维基数据项

我通过边界框部分没问题，但我无法确定“自修改以来”位。

This 是我能找到的最接近的示例，我试图从中完成这项工作：

SELECT ?place WHERE {
  SERVICE wikibase:box {
    ?place wdt:P625 ?location .
    # looks like cornerwest must be south of cornereast
    # otherwise you go around the globe
    # this is lng lat
    bd:serviceParam wikibase:cornerWest "Point(SW_LNG SW_LAT)"^^geo:wktLiteral .
    bd:serviceParam wikibase:cornerEast "Point(NE_LNG NE_LAT)"^^geo:wktLiteral .
  }
  ?place wdt:P31  ?placeCategory .
  ?place wdt:P625 ?placeCoords   .

  optional{ ?place wdt:P18 ?placePicture . }


  BIND (now() - ?modified as ?date_range)
  FILTER (?date_range > 2)
}

没有结果。

Answer 1

使用schema:dateModified。顺便说一句，Blazegraph 支持日期和时间算法：

SELECT ?place ?placeLabel ?location WHERE {
  BIND ((now() - "P7D"^^xsd:duration) AS ?date_)
  SERVICE wikibase:box {
    ?place wdt:P625 ?location   .
    bd:serviceParam wikibase:cornerSouthWest "Point(55.000 55.000)"^^geo:wktLiteral.
    bd:serviceParam wikibase:cornerNorthEast "Point(65.000 65.000)"^^geo:wktLiteral.
  }
  ?place schema:dateModified ?date .
  # hint:Prior hint:rangeSafe true .
  FILTER (?date >= ?date_)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ru". }
}

https://w.wiki/3E9Z

还有wikibase:timestamp谓词，比较辅助

如何在维基数据中查询最近一天修改过的项目？

How do I query Wikidata for items modified in the last day?

sparql

wikidata