填充不可变列表 "in a cycle"

Question

在我的 F# 学习过程中，我试图将以下带有列表的 C# 代码转换为 F# 等效代码。我认为很容易弄清楚代码的作用 - 例如，当 numberOfFilesList 是 [2, 2, 4, 3, 1] 时，然后是 endFilesToOpenList 是 [2, 4, 8, 11, 12 ]。 numberOfFilesList 和 endFilesToOpenList 都需要进一步的代码流。这是 C# 代码：

List<int> endFilesToOpenList = new List<int>();
List<int> numberOfFilesList = new List<int>();
int sum = 0;
for (int i = 0; i < (high - low + 1); i++)
{
    //myDictionary is of type Dictionary<string, int> 
    string myKey = $@"Here is a string depending on (low + 1) and (low + i)";  
    myDictionary.TryGetValue(myKey, out int value);
    numberOfFilesList.Add(value);
    sum += value;
    endFilesToOpenList.Add(sum);
}

虽然在此 C# 代码段中填充列表看起来非常简单直接，但我无法在 F# 中找到类似的简单等效项。 我的问题是：如何将此 C# 代码转换为外观整洁的 F# 代码？

我确实尝试用 F# 编写一些东西。代码虽然可以运行，但是看起来很复杂，尤其是填充endFilesToOpenList的代码。我认为必须有更好的方法来做到这一点。我不太好的 F# 尝试在这里：

let getOption j = 
    let i = j + 1  
    let myKey s1 s2 = $@"Here is a string depending on s1 and s2"   
    //myMap is of type Map<string, int>
    match i < (high - low + 1) with  
    | true  ->  
            match myMap.TryGetValue (myKey <| low + 1 <| low + i) with   
            | true, value -> Some(value, i)                                              
            | _  -> None    
    | false -> None  
let numberOfFilesList = List.unfold getOption (-1)
let sumAList list = List.fold(fun acc item -> acc + item) 0 list                                                       
let reducedList i = List.take i numberOfFilesList
let endFilesToOpenList = List.mapi(fun i item -> sumAList (reducedList <| i + 1)) numberOfFilesList

Answer 1

这应该可以满足您的要求：

let makeLists (myMap : Map<_, _>) =
    let numberOfFilesList =
        [
            for i = 0 to myMap.Count - 1 do
                match myMap |> Map.tryFind $"key{i}" with
                    | Some value -> yield value
                    | None -> ()
        ]
    let endFilesToOpenList =
        numberOfFilesList
            |> List.scan (+) 0
            |> List.skip 1
    numberOfFilesList, endFilesToOpenList

这里主要有两个概念：

使用list comprehension生成numberOfFilesList。
然后使用 List.scan 计算总值运行。

当然还有其他方法，但我认为这在精神上最接近您的要求。（请注意，我稍微简化了密钥格式以使逻辑更清晰。我认为一旦您了解了该功能的工作原理，您应该可以轻松地增强这部分内容。）

你可以这样测试：

let myMap =
    Map [
        "key0", 2
        "key1", 2
        "key2", 4
        "key3", 3
        "key4", 1
    ]        
let numberOfFilesList, endFilesToOpenList =
    makeLists myMap
printfn "numberOfFilesList: %A" numberOfFilesList
printfn "endFilesToOpenList: %A" endFilesToOpenList

输出符合您的要求：

numberOfFilesList: [2; 2; 4; 3; 1]
endFilesToOpenList: [2; 4; 8; 11; 12]

填充不可变列表 "in a cycle"

Populating immutable lists "in a cycle"

list

f#

cycle