如何将 Delphi 中的文件读入字节数组？

Question

我正在尝试将文件读入 Delphi XE2 中的字节数组。

这是我当前的代码：

function FileToBytes(const AName: string; var Bytes: TBytes): Boolean;
var
  Ms: TMemoryStream;
begin
  Result := False;
  if not FileExists(AName) then
    Exit;
  Ms := TMemoryStream.Create;
  try
    Ms.LoadFromFile(AName);
    if Ms.Size > 0 then
    begin
      Ms.Position := 0;
      MS.ReadBuffer(Bytes[0], Ms.Size);
      Result := True;
    end;
  finally
    Ms.Free;
  end;
end;

procedure runFile();
var
  Bytes: TBytes;
  OpFile: String;
begin
  OpFile := 'C:\Users\Kenny\Documents\calc.exe';
  Bytes := nil;
  if FileToBytes(OpFile, Bytes) then
  begin
    //do someting with Bytes(array of Byte)

  end;
end;

我在这一行遇到错误：

MS.ReadBuffer(Bytes[0], Ms.Size);

错误是：

access violation at 0x00404727: write of address 0x00000008

如能帮助解决此问题，我们将不胜感激。

Answer 1

你没有分配数组，这就解释了错误。您可以像这样修复您的代码：

Ms.LoadFromFile(AName);
SetLength(Bytes, Ms.Size);
Ms.Position := 0;
MS.ReadBuffer(Pointer(Bytes)^, Ms.Size);
Result := True;

请注意，我已经避免了检查零长度文件的需要，并使用了 Pointer(Bytes) 以便代码在范围检查处于活动状态时工作。

我还要指出，您的代码违反了我所说的 Delphi 内存流反模式。您将文件读入内存流，它本质上是一个字节数组。然后你从那个字节数组复制到另一个字节数组。您将整个文件写入两个单独的字节数组。这比必要的多了一个。最好这样写：

function FileToBytes(const AName: string; var Bytes: TBytes): Boolean;
var
  Stream: TFileStream;
begin
  if not FileExists(AName) then
  begin
    Result := False;
    Exit;
  end;
  Stream := TFileStream.Create(AName, fmOpenRead);
  try
    SetLength(Bytes, Stream.Size);
    Stream.ReadBuffer(Pointer(Bytes)^, Stream.Size);
  finally
    Stream.Free;
  end;
  Result := True;
end;

这样您就可以直接从文件读取到目标字节数组。

我不太喜欢把它作为一个函数，returns 一个布尔值来表示成功。除了文件不存在之外，还有很多方法可能导致代码失败。这些将导致您的设计出现异常。我更愿意看到纯粹基于异常的错误处理，或纯粹基于错误代码的错误处理。但不是您设计的混合方法。

正如 Andreas 在评论中指出的那样，您还可以使用 RTL 库函数 System.IOUtils.TFile.ReadAllBytes 来执行此任务。尽管由于许多设计问题，我个人倾向于避免使用整个 System.IOUtils 单元。虽然其中一些已在最近的版本中得到解决，但我相信 XE2 版本可能会有些问题。

如何将 Delphi 中的文件读入字节数组？

How do you read a file in Delphi into a byte array?

arrays

delphi

byte

delphi-xe2