需要修复向 table 动态插入值的过程

Question

我正在尝试使用动态 SQL 将值插入我的 table。但我正在为此苦苦挣扎！这是我的 table

CREATE TABLE CARS
(
    ID INTEGER PRIMARY KEY,
    Manufacturer VARCHAR2(1000),
    Model VARCHAR2(1000),
    Year INTEGER NOT NULL,
    Category VARCHAR2(1000) NOT NULL,
    Mileage NUMBER,
    FuelType VARCHAR2(1000),
    EngineVolume NUMBER,
    DriveWheels VARCHAR2(1000),
    GearBox VARCHAR2(1000),
    Doors VARCHAR2(1000),
    Wheel VARCHAR2(1000),
    Color VARCHAR2(1000),
    InteriorColor VARCHAR2(1000),
    VIN VARCHAR2(1000),
    LeatherInterior VARCHAR2(1000) NOT NULL,
    Price VARCHAR2(1000) NOT NULL,
    Clearence VARCHAR2(1000) NOT NULL
)

并且我创建了一个触发器，它会自动增加 id 列。

CREATE SEQUENCE cars_seq START WITH 93100;

CREATE OR REPLACE TRIGGER cars_id_inc 
BEFORE INSERT ON cars FOR EACH ROW
BEGIN
    :NEW.ID := CARS_SEQ.nextval;
END;

然后我创建了一个将值插入 cars table.

的过程

CREATE OR REPLACE PROCEDURE insert_all_cars (p_values VARCHAR2) IS
    v_stmt VARCHAR2(10000);
BEGIN
    v_stmt := 'INSERT INTO CARS '  || ' VALUES ' || p_values;
    EXECUTE IMMEDIATE v_stmt;
END;

当我尝试使用如下过程向 cars table 插入值时：

DECLARE 
    p_values VARCHAR2 := '(''new_manufacturer'', ''new_model'', ' || '2000' || ' ,''new_category'', ' || '2000' ||' ,''new_fueltype'', ' || '3.0' || 
    ' ,''new_drivewheels'',''new_gearbox'',''new_doors'',''new_wheel'',''new_color'',
    ''new_interior_color'',''new_vin'',''new_leather_interior'',''new_price'',''new_clearence'')';
BEGIN
    insert_all_cars(p_values);
END;

我遇到这种错误：

Error starting at line : 60 in command -
DECLARE 
    p_values VARCHAR2 := '(''new_manufacturer'', ''new_model'', ' || '2000' || ' ,''new_category'', ' || '2000' ||' ,''new_fueltype'', ' || '3.0' || 
    ' ,''new_drivewheels'',''new_gearbox'',''new_doors'',''new_wheel'',''new_color'',
    ''new_interior_color'',''new_vin'',''new_leather_interior'',''new_price'',''new_clearence'')';
BEGIN
    insert_all_cars(p_values);
END;
Error report -
ORA-06550: line 2, column 14:
PLS-00215: String length constraints must be in range (1 .. 32767)
06550. 00000 -  "line %s, column %s:\n%s"
*Cause:    Usually a PL/SQL compilation error.
*Action:

也尝试输入不带引号的数字得到了同样的错误。我该如何解决？

Answer 1

您没有在匿名 pl/sql 块中定义 p_values 的长度。但是为什么要用动态的sql呢？这是一个非常糟糕的用例。为什么不是这个？

create or replace procedure insert_all_cars (
    p_manufacturer VARCHAR2,
    p_model VARCHAR2,
    p_year INTEGER,
    p_category VARCHAR2,
    p_mileage NUMBER,
    p_fueltype VARCHAR2,
    p_enginevolume NUMBER,
    p_drivewheels VARCHAR2,
    p_gearbox VARCHAR2,
    p_doors VARCHAR2,
    p_wheel VARCHAR2,
    p_color VARCHAR2,
    p_interiorcolor VARCHAR2,
    p_vin VARCHAR2,
    p_leatherinterior VARCHAR2,
    p_price VARCHAR2,
    p_clearence VARCHAR2) is
begin
    insert into cars (
        Manufacturer, 
        Model,
        Year,
        Category,
        Mileage,
        FuelType,
        EngineVolume,
        DriveWheels,
        GearBox,
        Doors,
        Wheel,
        Color,
        InteriorColor,
        VIN,
        LeatherInterior,
        Price,
        Clearence )
    values (
        p_manufacturer,
        p_model,
        p_year,
        p_category,
        p_mileage,
        p_fueltype,
        p_enginevolume,
        p_drivewheels,
        p_gearbox,
        p_doors,
        p_wheel,
        p_color,
        p_interiorcolor,
        p_vin,
        p_leatherinterior,
        p_price,
        p_clearence );
end;
/

然后是这个：

begin
    insert_all_cars (
        p_manufacturer    => 'new_manufacturer',
        p_model           => 'new_model',
        p_year            => 2000,
        p_category        => 'new_category',
        p_mileage         => 2000,
        p_fueltype        => 'new_fueltype',
        p_enginevolume    => 3.0,
        p_drivewheels     => 'new_drivewheels',
        p_gearbox         => 'new_gearbox',
        p_doors           => 'new_doors',
        p_wheel           => 'new_wheel',
        p_color           => 'new_color',
        p_interiorcolor   => 'new_interior_color',
        p_vin             => 'new_vin',
        p_leatherinterior => 'new_leather_interior',
        p_price           => 'new_price',
        p_clearence       => 'new_clearence'
    );
    commit;
end;
/

需要修复向 table 动态插入值的过程

Needs fixing a procedure for inserting values to the table dynamically

oracle

plsql

dynamic-sql