如何在 fish 中为 HTTPie 的“@”路径选项启用制表符补全？

Question

HTTPie 接受路径作为包含 @ 符号的选项的参数。不幸的是，它们似乎不适用于 fish 中的 shell 完成。相反，该选项被视为不透明字符串。

为了坚持使用 the file upload example from the HTTPie documentation 和位于 ~/files/data.xml 的文件，我希望能够在键入时用 Tab 键完成文件名：

http -f POST pie.dev/post name='John Smith' cv@~/files/da<TAB>

但是，没有完成。

我已经安装了 completions for fish from the HTTPie project，它们适用于短参数和长参数。不过，此文件并未指定如何完成 @ 参数。

此外，我研究了指定我自己的完成，但我无法找到一种方法来使用任意前缀完成工作文件。

我如何为 HTTPie 实现这些路径参数的完成？

Answer 1

目前，HTTPie 的 fish 补全没有带 @ 的文件路径参数的补全。关于这个还有更一般的GitHub Issue open。

如果这是您想要为自己或项目做的事情，您可以从 HTTPie plugin for zsh+ohmyzsh 中获得 fish 实现的一些灵感，实现您的目标期望的行为。

Answer 2

我设法完成了路径参数的制表符补全，但有一些注意事项。

这增加了补全：

complete -c http --condition "__is_httpie_path_argument" -a "(__complete_httpie_path_argument (commandline -t))"

具有以下功能：

function __is_httpie_path_argument
    set -l arg (commandline -t)
    __match_httpie_path_argument --quiet -- $arg
end

function __match_httpie_path_argument
    string match --entire --regex '^([^@:=]*)(@|=@|:=@)(.*)$' $argv
end

function __complete_httpie_path_argument
    __complete_httpie_path_argument_helper (__match_httpie_path_argument -- $argv[1])
end

function __complete_httpie_path_argument_helper
    set -l arg $argv[1]
    set -l field $argv[2]
    set -l operator $argv[3]
    set -l path $argv[4]

    string collect $field$operator(__fish_complete_path $path)
end

需要注意的是，这不会扩展任何变量，也不会扩展波浪号 ~。它基本上只适用于普通路径——相对或绝对路径。

如何在 fish 中为 HTTPie 的“@”路径选项启用制表符补全？

How can I enable tab-completion for `@` path options to HTTPie in fish?

tab-completion

fish

httpie