将币安费用放入电子表格（Google 张）

Question

我正在尝试从 Binance 费用 (https://www.binance.com/en/fee/depositFee) 中导入 table 到 Google 表格（购买我正在尝试进入 MS Excel）。

当我获取数据时，我不知道如何为每种网络类型拆分文件。

现在，我有这样的数据：

=IMPORTHTML("https://www.binance.com/en/fee/depositFee"; "table"; 0)

谢谢！！！

Answer 1

一个解决方案是，在像您一样导入数据后，将每一行拆分如下

=iferror(transpose(flatten(arrayformula(transpose(split(transpose(C3:F3),char(10)))))),"")

您将获得多个 4 列块。最后你可以这样分组数据，假设最多有 4 个块：

=query({query( 'raw data'!A3:V,"select A,B,G,H,I,J");query('raw data'!A3:V,"select A,B,K,L,M,N");query('raw data'!A3:V,"select A,B,O,P,Q,R");query('raw data'!A3:V,"select A,B,S,T,U,V")},"select * where Col3<>'' order by Col1")

https://docs.google.com/spreadsheets/d/1JCjJywK9qPprynX2byvAnU7jS4S9cAYmHAfLcuyW3oQ/edit?usp=sharing

Answer 2

我可以在一个单元格中提供一个解决方案*，该公式适用于您的 importrange 数据（显示在下面的单元格 H1 中）：

=arrayformula(
{query(IFERROR(array_constrain(
{"Coin/Token","Full Name","Network","Minimum Withdrawal","Deposit fee","Withdrawal Fee";
flatten(split(rept("|"&A3:A,LEN(regexreplace($C3:$C,"[^\n]",""))+1),"|"))
,flatten(split(rept("|"&B3:B,LEN(regexreplace($C3:$C,"[^\n]",""))+1),"|"))
,flatten(split(C3:C,CHAR(10)))
,flatten(split(D3:D,CHAR(10)))
,flatten(split(E3:E,CHAR(10)))
,flatten(split(F3:F,CHAR(10)))
},
max(IF(A3:A<>"",LEN(regexreplace($C3:$C,"[^\n]",""))+1,))*COUNTA(A3:A),
6)
,),"where Col1 is not null",0)
})

扩展 C、D、E 和 F 列中的单元格，其中 C 中有多个项目。它还会重复 A 和 B.

列中的值

列 D 和 F 正确转换为数字。

公式更新为 Mike Steelson enhancements and player0 LEN/REGEXREPLACE。

Answer 3

您只需要：

=INDEX(TRIM(TRANSPOSE(SPLIT(FLATTEN(QUERY({REPT(ARRAY_CONSTRAIN(
 IMPORTHTML("https://www.binance.com/en/fee/depositFee", "table", 1), 9^9, 2)&
 "×", 1+LEN(REGEXREPLACE(INDEX(""&
 IMPORTHTML("https://www.binance.com/en/fee/depositFee", "table", 1),, 3), 
 "[^\n]+", ))), REGEXREPLACE(QUERY(
 IMPORTHTML("https://www.binance.com/en/fee/depositFee", "table", 1)&
 "×", "select Col3,Col4,Col5,Col6", 1), "\n", "×")},,9^9)), "×"))))

将币安费用放入电子表格（Google 张）

Get Binance Fees into Spreadsheets (Google Sheets)

google-sheets

binance