Excel 函数 return COMBIN() 中的嵌套 SEQUENCE

Question

我当前的功能是：

=SUM(COMBIN(5,SEQUENCE($A,,$A,-1)) * COMBIN(4,SEQUENCE($A,,$A,-1)))

其中 $A$1 = 任何可能的整数。因此，例如，如果它是 3，它将 return 120 即

组合（5...）	组合（4...）	总和
10	4	40
10	6	60
5	4	20
		120

我需要更改公式，以便最终数字基于 $A$1 输入数字的嵌套序列，因此使用相同的示例，其中 $A$1 = 3 结果为 220，实际上是对$A$1 递减 1 直到达到 1 的公式，即

组合（5...）	组合（4...）	总和
10	4	40
10	6	60
5	4	20
10	6	60
5	4	20
5	4	20
		220

或实际上=SUM(COMBIN(5,SEQUENCE($A,,$A,-1)) * COMBIN(4,SEQUENCE($A,,$A,-1)), COMBIN(5,SEQUENCE($A-1,,$A-1,-1)) * COMBIN(4,SEQUENCE($A-1,,$A-1,-1)), COMBIN(5,SEQUENCE($A-2,,$A-2,-1)) * COMBIN(4,SEQUENCE($A-2,,$A-2,-1)))

但是因为我不知道 $A$1 是什么，所以我不能这样写，因为我不知道 $A$1-x 什么时候会达到 1 并因此停止求和。

Answer 1

你可以用三角矩阵来做 - 我没有看到任何特别的理由从起始值开始倒数，你可以只数到它所以矩阵看起来像这样：

1 -1 -1
1  2 -1
1  2  3

未使用带 -1 的位置。

在 Excel 365 中，您可以通过 2 个步骤来说明这一点：

=IF(SEQUENCE(1,A1)>SEQUENCE(A1,1),-1,SEQUENCE(1,A1))

获取（比如）C1 中的矩阵和

=SUM(IFERROR(COMBIN(4,C1#)*COMBIN(5,C1#),0))

完成组合

或者使用像这样的 Let 公式来组合这两个步骤：

=LET(
rowSeq,SEQUENCE(A1),
colSeq,SEQUENCE(1,A1),
matrix,IF(colSeq>rowSeq,-1,colSeq),
SUM(IFERROR(COMBIN(4,matrix)*COMBIN(5,matrix),0)))

或更短：

=LET(
rowSeq,SEQUENCE(A1),
colSeq,SEQUENCE(1,A1),
SUM(IF(colSeq>rowSeq,0,COMBIN(4,colSeq)*COMBIN(5,colSeq)))
)

Lambda 版本

定义 Lambda 函数 SumOfCombo:

=LAMBDA(N,IF(N<=0,0,SUM(COMBIN(4,SEQUENCE(N))*COMBIN(5,SEQUENCE(N)))+SumOfCombo(N-1)))

并用

调用它

=SumOfCombo(A1)

Excel 函数 return COMBIN() 中的嵌套 SEQUENCE

Excel function to return a nested SEQUENCE within COMBIN()

excel

sequence

excel-formula