multiboot2 header 正确进入 "EFI amd64 machine state with boot services enabled" - hlt 指令不起作用？

Question

我有一个基本的 start.asm（nasm 汇编程序）和一个 multiboot2_header.asm 的简单设置，它们在编译后链接在一起。 multiboot2 header 位于最终 ELF64-x86_64 文件的开头。要运行呢，我用QEMU -> OVMF (UEFI) -> GRUB -> <my-binarỳ>。当我使用最小的 multiboot2 header 时，一切正常：我处于 32 位模式，我可以设置自己的堆栈和调用函数。为了验证这一点，我检查了 QEMU 中的寄存器。但现在我想启动到 EFI amd64 machine state with boot services enabled，它在 3.5 multiboot2 规范 [1] 部分中定义，但这会导致问题。

我如何努力实现我的目标： 规范告诉我们，multiboot2 header 必须包含两个标签 EFI boot services tag: leaves UEFI boot services enabled 和 EFI amd64 entry address tag of Multiboot2 header tag。我相信我做对了（下面的代码）。

问题（更新 2021-06-17） 经过更多调查后，看起来我的方法大部分（？）是正确的。问题是，我的 hlt 指令被忽略了。这样，执行的代码比预期的多，一些执行中毒 eax。如果我把我的start-symbol里的hlt改成无限无条件的jmp到这个jmp的地址，eax里的值就对了！ (更新结束)

multiboot2-header.asm:

; This file uses "Netwide Assembler Syntax" and can be compiled by running
; `nasm -f elf64 multiboot2_header.asm -o multiboot2_header.o`
;
; External symbol, that comes "start.asm"
EXTERN start

ALIGN   8  ; according to spec, the header must be 64-bit (8 byte) aligned
section .multiboot_header

    header_start:
        ;   dd => int 32, see https://www.cs.uaf.edu/2017/fall/cs301/reference/x86_64.html
        dd  0xe85250d6                ; magic number (multiboot 2 spec)
        dd  0                         ; architecture 0 (protected mode i386; spec doesn't specify many options)
        dd  header_end - header_start ; header length
        ;   checksum
        dd  0x100000000 - (0xe85250d6 + 0 + (header_end - header_start))

        ; OPTIONAL MULTIBOOT2 TAGS (additional to required END TAG)
        ; In order to boot into "EFI amd64 machine state with boot services enabled" (3.5 in Spec, 2021-06)
        ; machine state, we must specify a few additional tags:
        ;
        ; ------------------------------------------------------------------------------------
        ; "EFI boot services tag": leaves UEFI boot services enabled: its our task to exit them
        ALIGN   8       ; alignment in bits, according to multiboot2 spec, tags are 8-byte (64bit) aligned
        dw      7       ; type  (16bit)
        dw      0       ; flags (16bit)
        dd      8       ; size  (32bit)
        ; ------------------------------------------------------------------------------------
        ; "EFI amd64 entry address tag of Multiboot2 header tag"
        ALIGN   8
        dw      9       ; type  (16bit)
        dw      0       ; flags (16bit)
        dd      12      ; size  (32bit)
        ; TODO I'm not entirely sure how this works together with the "start" symbol from the linker script:
        ;  perhaps the start symbol in the linker script is a fallback, if this is not found
        dd      start   ; entry_addr (32bit)
        ; ------------------------------------------------------------------------------------
        ; REQUIRED END TAG
        ALIGN   8
        dw      0       ; type  (16bit)
        dw      0       ; flags (16bit)
        dd      8       ; size  (32bit)
    header_end:

PS：Rust 工具 bootinfo [2] 正确识别了 multiboot2 header 和我最终 ELF 中指定的标签。

Answer 1

我最初的方法是正确的，实际上是正确的。由于两个误解，我无法正确检查：

我实际上处于 64 位长模式但尝试执行 32 位代码
hlt 指令没有工作，因为 QEMU 得到了一些中断并且 hlt 被清除了

如果起始符号如下所示，您可以在 startup/after 切换期间轻松验证 QEMU 中的寄存器：

GLOBAL start

SECTION .text

; produce x-bit x86 code (even if this will be an ELF-64 file)
[BITS 64]

    start:
        mov r12, 0xffffeeeeddddcccc   ; verify that we are in 64-bit mode (otherwise this fails)
        cli ; without clear interrupts, the hlt is ignored (I don't know what interrupt comes.. maybe the key input in qemu)
        hlt

multiboot2 header 正确进入 "EFI amd64 machine state with boot services enabled" - hlt 指令不起作用？

multiboot2 header to properly go into "EFI amd64 machine state with boot services enabled" - hlt instruction not working?

x86

x86-64

nasm

grub

multiboot