请给我这个公式的 ArrayFormula

Question

我要完成第一栏

公式为：
=textjoin(char(10),false,A4:F4)

当我转换为 Arrayfromula 时：
=transpose(split(textjoin(char(10),false,{ArrayFormula("~"&A4:A),A4:F}),"~"))

Editable Sheet link

在我的 Arrayformula 中，第一个值重复，请帮助！

编辑：

有没有办法实现Arrayformula 1（两列）& Arrayformula 2（单列）？

号码sheet:
（基本不包含0值的单元格）

公式甚至可以将字符串作为数据使用，而不是强制数字，如下所示：

字符串和数字 sheet:
(基本不包含值为0&NULL的单元格)

Answer 1

尝试：

=ARRAYFORMULA(REGEXREPLACE(REGEXREPLACE(FLATTEN(QUERY(TRANSPOSE(
 TO_TEXT(A4:F6)&"×"),,9^9)), "×", CHAR(10)), " ", ))

更新：

=ARRAYFORMULA({IF(TRIM(FLATTEN(QUERY(TRANSPOSE(A4:F),,
 9^9)))="",,JOIN(CHAR(10), A1:F1)), 
 REGEXREPLACE(REGEXREPLACE(REGEXREPLACE(FLATTEN(QUERY(TRANSPOSE(
 TO_TEXT(SUBSTITUTE(A4:F, " ", "♀"))&"×"),,
 9^9)), "×", CHAR(10)), " |\n$", ), "♀", " ")})

=ARRAYFORMULA(IF(TRIM(FLATTEN(QUERY(TRANSPOSE(A4:F),,9^9)))="",,
 REGEXREPLACE(REGEXREPLACE(REGEXREPLACE(FLATTEN(QUERY(TRANSPOSE(
 TO_TEXT(SUBSTITUTE(IF(A4:F="",,A1:F1&": "&A4:F), " ", "♀"))&"×"),,
 9^9)), "×", CHAR(10)), " |\n$", ), "♀", " ")))

请给我这个公式的 ArrayFormula

Please give me an ArrayFormula for this formula

line-breaks

google-sheets

array-formulas

google-sheets-formula

更新：