Groovy JsonBuilder 在 toString() 时的奇怪行为

Question

我需要创建一个 json 用作 http.request 中的正文。我能够动态构建 json，但我注意到在调用 builder.toString() 两次时出现了一个奇怪的行为。结果 json 完全不同。我可能认为这与某种缓冲区有关。我一直在阅读文档，但找不到好的答案。这是一个测试代码。

import groovy.json.JsonBuilder

def builder = new JsonBuilder()

def map = [
    catA: ["catA-element1", "catA-element2"],
    catB:[],
    catC:["catC-element1"]
]

def a = map.inject([:]) { res, k, v ->
    def b = v.inject([:]) {resp, i ->
        resp[i] = k
        resp
    }
    res += b
}
println a

def root = builder.query {
    bool {
        must a.collect{ k, v ->
            builder.match {
                "$v" k
            }
        }
    }
    should([
        builder.simple_query_string {
            query "text"
        }
    ])
}
println builder.toString()
println builder.toString()

这将打印以下行。注意最后两行

[catA-element1:catA, catA-element2:catA, catC-element1:catC]
{"query":{"bool":{"must":[{"match":{"catA":"catA-element1"}},{"match":{"catA":"catA-element2"}},{"match":{"catC":"catC-element1"}}]},"should":[{"simple_query_string":{"query":"text"}}]}}
{"match":{"catC":"catC-element1"}}

在我的代码中，我可以轻松地将第一个 toString() 结果发送到一个变量，并在需要时使用它。但是，为什么调用不止一次就变了？

Answer 1

我认为这是因为您在闭包 bool 中使用了 builder。如果我们在打印结果之前创建 print builder.content（buider.toString() 正在调用 JsonOutput.toJson(builder.content)），我们会得到：

[query:[bool:ConsoleScript54$_run_closure3$_closure6@294b5a70, should:[[simple_query_string:[query:text]]]]]

将println builder.content添加到bool闭包我们可以看到builder.content在评估闭包时被修改：

def root = builder.query {
    bool {
        must a.collect{ k, v ->
            builder.match {
                "$v" k
                println builder.content
            }
        }
    }
    should([
        builder.simple_query_string {
            query "text"
        }
    ])
}

println JsonOutput.toJson(builder.content)
println builder.content

以上结果：

[query:[bool:ConsoleScript55$_run_closure3$_closure6@39b6156d, should:[[simple_query_string:[query:text]]]]]
[match:[catA:catA-element1]]
[match:[catA:catA-element2]]
{"query":{"bool":{"must":[{"match":{"catA":"catA-element1"}},{"match":{"catA":"catA-element2"}},{"match":{"catC":"catC-element1"}}]},"should":[{"simple_query_string":{"query":"text"}}]}}
[match:[catC:catC-element1]]

你可以很容易地用不同的构建器来避免里面的闭包：

def builder2 = new JsonBuilder()

def root = builder.query {
    bool {
        must a.collect{ k, v ->
            builder2.match {
                "$v" k
            }
        }
    }
    should([
        builder.simple_query_string {
            query "text"
        }
    ])
}

甚至更好：

def root = builder.query {
    bool {
        must a.collect({ k, v -> ["$v": k] }).collect({[match: it]})
    }
    should([
        simple_query_string {
            query "text"
        }
    ])
}

Groovy JsonBuilder 在 toString() 时的奇怪行为

Groovy JsonBuilder strange behavior when toString()

json

groovy

groovy-console

jsonbuilder