Wikidata SPARQL：如果可用，如何按日期过滤？

Question

我想要德国所有拨号代码和邮政编码的列表，但有些城镇有旧邮政编码的数据，这个查询 returns 其中之一，但不是最新的：

SELECT DISTINCT ?item ?itemLabel ?officialName ?dialcode ?zipCode
WHERE { 
    ?item p:P31/ps:P31/wdt:P279* wd:Q262166;
           wdt:P17 wd:Q183;     # Country = Germany
           wdt:P131 wd:Q10489;  # County
           wdt:P281 ?zipCode; wdt:P473 ?dialcode; .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    OPTIONAL{?item wdt:P1448 ?officialName .}
}                                               
ORDER BY DESC(?zipCode) ?dialcode

Hautzenberg 镇 returns W-8395 作为邮政编码而不是 94051，因为这是数据库中为数不多的具有邮政编码开始和结束日期的城镇之一。但是大多数邮政编码都没有任何日期。如果没有给出日期，它还应该提供邮政编码。

这是Hautzenberg的数据：https://www.wikidata.org/wiki/Q255888

Answer 1

确实是Hautzenberg returns 4个代码，其中还有94051。

如果您只想要 94051，则必须按日期过滤。

启发式地，您可以过滤掉确实具有 end time:

的声明

SELECT DISTINCT ?item ?itemLabel ?officialName ?dialcode ?zipCode
WHERE { 
    ?item p:P31/ps:P31/wdt:P279* wd:Q262166;
          wdt:P17 wd:Q183;     # Country = Germany
          wdt:P131 wd:Q10489;  # County
          p:P281 ?zipCodeStmt;
          wdt:P473 ?dialcode; .
  ?zipCodeStmt ps:P281 ?zipCode;
  FILTER NOT EXISTS { ?zipCodeStmt pq:P582 ?endTime . } # Filtering out old postal codes
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  OPTIONAL { ?item wdt:P1448 ?officialName . }
}                                               
ORDER BY DESC(?zipCode) ?dialcode

Wikidata SPARQL：如果可用，如何按日期过滤？

Wikidata SPARQL: How to filter by date if available?

sparql

wikidata