将多个 SAS 数据集写入一个 Excel sheet

Question

我正在使用 SAS Enterprise Guide 7.15。我想将几个数据集导出到多个 excel sheet 中（每个 sheet 中的多个表）。我正在使用 ODS，即使我正在设置 sheet_interval="none"，在两个表之后它会破坏页面，并将下一个表推到另一个 excel sheet.

这是我的代码示例，这里导出了 2 个表，稍后我想在同一个表中再添加 20 个表 sheet:

%macro table_1;

    proc report data=table_1 out=sheet_1 headline split='#' spacing=1 nowd missing
    style(summary)={font_weight=bold}
    columns 
    
    segment     
    diff        
    cnt_old         
    cnt_new
    ;
    
    
    compute before _page_/style=[font_size=3 font_weight=bold foreground=white background=Dark Blue];
    line "table 1";
    line ' ';
    line 'Number of Customers';
    endcomp;
    compute after;
    endcomp
    run;

%mend table_1;

%macro table_3;

    proc report data=table_3 out=sheet_1 headline split='#' spacing=1 nowd missing
    style(summary)={font_weight=bold}
    columns 
    
    FinalRiskRating 
    diff
    cnt_old         
    cnt_new;
    
    
    compute before _page_/style=[font_size=3 font_weight=bold foreground=white background=Dark Blue];
    line "table 3";
    
    endcomp;
    compute after;
    endcomp
    run;

%mend table_3;

%table_1; %table_3;


%let shk = table_1 + table_3;
ods path work.temptemp(update) sasuser.templat(update) sashelp.tmplmst(read);
ods path show;
Options mprint mlogic symbolgen nobyline;
ods listing close;

%macro b;

    %do i=1 %to 2;
    %let mshk=%scan(&shk., &i.,+);
    /*ods tagsets.excelxp options(SHEET_INTERVAL='NONE' PAGEBREAK="NO"  sheet_name="sheet1" ABSOLUTE_COLUMN_WIDTH='8' AUTOFIT_HEIGHT='yes' embed_titles_once = 'yes' embedded_titles='yes');*/
    ods tagsets.excelxp options(sheet_interval="none" sheet_name="sheet1" ABSOLUTE_COLUMN_WIDTH='8' AUTOFIT_HEIGHT='yes' embed_titles_once = 'yes' embedded_titles='yes');
    %&mshk.;
    %end;

%mend b;

ods tagsets.excelxp file="&reportlocation";

%b;
ods tagsets.excelxp close;
ods _all_ close;
;

Answer 1

我怀疑是因为你没有在初始 ods tagsets.excelxp 上指定 sheet_interval='none'。

和你一样，第一个例子有这个问题：

ods tagsets.excelxp  file="h:\temp\test.xls";
ods tagsets.excelxp options(sheet_interval='none');
proc print data=sashelp.class;
run;
ods tagsets.excelxp options(sheet_interval='none');
proc print data=sashelp.class;
run;
ods tagsets.excelxp close;

但这按预期工作：

ods tagsets.excelxp options(sheet_interval='none') file="h:\temp\test.xls";
proc print data=sashelp.class;
run;
proc print data=sashelp.class;
run;
ods tagsets.excelxp close;

有趣的是，如果您删除 second 一个，它仍然有效 - 所以它不完全是不在第一行，而是新的选项语句。我想这会以某种方式重置它。但在你的情况下，真的没有理由不把这些细节中的任何一个放在最初的 ods tagsets.excelxp 声明中。

ODS EXCEL 不是那样的，它总是一个 sheet。如果可以的话，无论如何我都建议使用它。

将多个 SAS 数据集写入一个 Excel sheet

Write multiple SAS datasets into one Excel sheet

sas

export-to-excel

sas-macro

enterprise-guide

sas-dis