获取延迟扩展值到函数输出

Question

这是一个 windows 命令片段：

:moveFiles
    @for /f %%R in ('dir /b current') do (
        @echo ___
        @echo Moving %%R to FTP server.
        %java_cmd% -jar f17ftp.jar -dput -file:%%R  %select%
        if 1 neq 0 (
            @echo Transfer of %%R failed.
            call :readLog
            echo %log%
            %java_cmd% -cp SQLQueryXML.jar com.saliencrgt.chums.AlertMessage "Contents of ftp log are:<br/><br>"%log%
        ) else (
            @echo Transfer of %%R succeeded.
            move current\%%R xmlfiles 1> nul
        )
    )
    exit /b

:readLog
    setlocal enableextensions enabledelayedexpansion
    @for /F "delims=" %%x in (f17ftp.debug.log) do (
        if .!build!==. (set build=%%x) else (set build=!build!,%%x)
    )
    endlocal & set log=!build!
    exit /b

我正在尝试将文件的内容放入变量中作为参数发送给 java class readLog 函数确实读取文件，如果我回显 !build!在 endlocal 之前，文件内容会打印到控制台。

我可以将“log”设置为常量而不是 !build!变量，我在调用函数中看到它，但我无法从函数中获取延迟变量值。

Answer 1

这是我希望您的 :readLog 标签部分看起来如何的简单示例：

:readLog
    @set "log="
    @setlocal enableextensions enabledelayedexpansion
    @set "build="
    @for /f "usebackq delims=" %%x in ("f17ftp.debug.log") do @(
        if not defined build (set "build=%%x") else set "build=!build!,%%x"
    )
    @endlocal & set "log=%build%"
    @exit /b

但是要查看它，因为它仍在括号内定义，您可能会发现您的 :moveFiles 标签部分也需要启用延迟扩展，然后 echo !log!不是 echo %log%.

因此您可能会发现更像这样的东西更适合您：

:moveFiles
    @for /f "eol=? delims=" %%R in ('dir /b "current" 2^>nul') do @(
        echo ___
        echo Moving %%R to FTP server.
        "%java_cmd%" -jar "f17ftp.jar" -dput -file:"%%R"  %select%
        if errorlevel 1 (
            echo Transfer of %%R failed.
            setlocal enabledelayedexpansion
            set "log="
            set "build="
            call :readLog
            echo !log!
            "%java_cmd%" -cp "SQLQueryXML.jar" com.saliencrgt.chums.AlertMessage "Contents of ftp log are:<br/><br>"!log!
            endlocal
        ) else (
            echo Transfer of %%R succeeded.
            move "current\%%R" "xmlfiles" 1>nul
        )
    )
    @exit /b

:readLog
    @for /f "usebackq delims=" %%x in ("f17ftp.debug.log") do @(
        if not defined build (set "build=%%x") else set "build=!build!,%%x"
    )
    @set "log=%build%"
    @exit /b

获取延迟扩展值到函数输出

Getting delayed expansion value to function output

windows

batch-file

cmd

delayedvariableexpansion