如何在 CPS 中构造更高级别的 Coyoneda 类型的值？

Question

{-# LANGUAGE RankNTypes #-}

newtype Coyoneda f a = Coyoneda {
  uncoyo :: forall b r. ((b -> a) -> f b -> r) -> r
}

coyoneda f tx = Coyoneda (\k -> k f tx)

我认为 Coyoneda 应该通过模拟具有更高级别类型的存在来工作，但我无法构造这种类型的值。 coyoneda 辅助函数不进行类型检查，因为对于术语 k f tx 而言，更高级别的类型变量 b 会超出其范围。

但是，我想不出另一种实现方式coyoneda。有可能吗？

Answer 1

newtype 不太正确。以下作品：

newtype Coyoneda f a = Coyoneda {
  uncoyo :: forall r. (forall b. (b -> a) -> f b -> r) -> r
}

coyoneda f g = Coyoneda (\k -> k f g)

Answer 2

类型 T 同构于

forall r . (T -> r) -> r

由米田同构

在你的情况下，

forall b r. ((b -> a) -> f b -> r) -> r
~=  -- adding explicit parentheses
forall b . (forall r. ((b -> a) -> f b -> r) -> r)
~=  -- uncurrying
forall b . (forall r. ((b -> a, f b) -> r) -> r)
~=  -- Yoneda
forall b . (b -> a, f b)

这不是您想要的。要使用 coyoneda，您需要改为建模 existential 类型：

exists b . (b -> a, f b)

所以，让我们把它变成 forall

exists b . (b -> a, f b)
~=  -- Yoneda
forall r . ((exists b . (b -> a, f b)) -> r) -> r
~=  -- exists on the left side of -> becomes a forall
forall r . (forall b . (b -> a, f b) -> r) -> r
~=  -- currying
forall r . (forall b . (b -> a) -> f b -> r) -> r

因此，这是您需要在 Coyoneda 定义中使用的正确编码。

如何在 CPS 中构造更高级别的 Coyoneda 类型的值？

How to construct values of a higher-rank Coyoneda type in CPS?

haskell

unification

higher-rank-types