Azure Data Bricks 诊断设置的 ARM 模板

Question

我能够在门户中配置 azure data bricks 的诊断设置，我需要一个 ARM 模板来自动创建 azure data bricks 的诊断设置。

如果我这边需要任何其他信息，请告诉我。

提前致谢

Answer 1

Azure Databricks Workspace 的诊断设置与其创建是分开配置的 - 您可以使用 Azure Monitor 的标准 ARM 模板，您可以在 documentation 中找到它。您只需要 select 您想要启用的诊断类别，并相应地修改 ARM 模板（完整的类别列表可以在 UI 中找到，这里是部分列表：“dbfs”， “集群”、“账户”、“工作”、“笔记本”、“ssh”、“工作区”、“秘密”、“sqlPermissions”、“instancePools”）。

如果您能够使用 Terraform，您也可以通过它启用诊断设置，如下所示：

data "azurerm_databricks_workspace" "example" {
  name                = var.workspace_name
  resource_group_name = var.resource_group
}

data "azurerm_eventhub_namespace_authorization_rule" "test" {
  name                = "test"
  resource_group_name = var.resource_group
  namespace_name      = var.evhub_ns_name
}

resource "azurerm_monitor_diagnostic_setting" "test" {
  name               = "test"
  target_resource_id = data.azurerm_databricks_workspace.example.id
  eventhub_authorization_rule_id = data.azurerm_eventhub_namespace_authorization_rule.test.id
  eventhub_name = var.evhub_name

  dynamic "log" {
    for_each = var.enabled_log_types
    content {
      category = log.value
      enabled = true
    }
  } 
}

variable resource_group {
  type        = string
  description = "Resource group to deploy"
}

variable region {
  type        = string
  description = "Region to deploy"
}

variable evhub_ns_name {
  type        = string
  description = "Name of eventhub namespace"
}

variable evhub_name {
  type        = string
  description = "Name of EventHubs topic"
}

variable workspace_name {
  type = string
  description = "The name of DB Workspace"
}

variable enabled_log_types {
  type        = list(string)
  description = "List of the log types to enable"
  default     = ["dbfs", "clusters", "accounts", "jobs", "notebook", "ssh",
    "workspace", "secrets", "sqlPermissions", "instancePools"]
}

Azure Data Bricks 诊断设置的 ARM 模板

ARM template for Azure Data Bricks Diagnostic settings

azure-databricks

arm-template

azure-diagnostics