XSLT 1.0：如何根据值确定节点的位置

Question

感谢您抽出宝贵时间！

我正在尝试根据节点的值获取节点的位置，以便获得相应的条目。请让我给你举个例子，这样会更容易解释。

这是来源XML：

<?xml version="1.0" encoding="UTF-8"?>
<sampleSourceXML>
    <Table>
        <Header>
            <Column>Name</Column>
            <Column>Surname</Column>
            <Column>Title</Column>
        </Header>
        <Body>
            <Row>
                <Entry>James</Entry>
                <Entry>Bond</Entry>
                <Entry>Mr</Entry>
            </Row>
            <Row>
                <Entry>Harry</Entry>
                <Entry>Potter</Entry>
                <Entry>Mr</Entry>
            </Row>
        </Body>
    </Table>
</sampleSourceXML>

这是我想要实现的结果 XML：

<?xml version="1.0" encoding="UTF-8"?>
<sampleResultXML>
    <Person>
        <FirstName>James</FirstName>
        <LastName>Bond</LastName>
        <Title>Mr</Title>
    </Person>
    <Person>
        <FirstName>Harry</FirstName>
        <LastName>Potter</LastName>
        <Title>Mr</Title>
    </Person>
</sampleResultXML>

我用这个 XSLT 试过了：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>
    
    <xsl:template match="/">
        <xsl:element name="sampleResultXML">
            <xsl:for-each select="sampleSourceXML/Table/Rows/Row">
                <xsl:element name="Person">
                    <xsl:element name="FirstName">
                        <xsl:value-of select="./Entry[1]/text()"></xsl:value-of>
                    </xsl:element>
                    <xsl:element name="LastName">
                        <xsl:value-of select="./Entry[2]/text()"></xsl:value-of>
                    </xsl:element>
                    <xsl:element name="Title">
                        <xsl:value-of select="./Entry[3]/text()"></xsl:value-of>
                    </xsl:element>
                </xsl:element>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

这有效。

但是！来源 XML 可以有不同的顺序。例如，Title 元素可以位于 Name 元素之上。所以我的 XSLT 中的硬编码位置（例如 Entry[3]）将不再起作用。

header订单和入场订单总是对应的。因此，如果列标题位于位置 3，则对应的行也将如此。

所以我需要一种方法来动态获取 Title 元素的位置。所以我必须遍历 Column 元素，直到到达值为“Title”的元素。这个位置我想我会保存在一个变量中（例如 Position_Title），这样我以后可以像这样填充值：

<xsl:element name="Title">
  <xsl:value-of select="./Entry[$Position_Title]/text()"></xsl:value-of>
</xsl:element>

但是我一直没能找到方法...

你有什么想法可以实现吗？

谢谢！

尼克

编辑：感谢迈克尔的帮助！这是我使用的最终 XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
    <xsl:template match="/sampleSourceXML">
        <xsl:variable name="cols" select="Table/Header/Column"/>
        <sampleResultXML>
            <xsl:for-each select="Table/Body/Row">
                <Person>
                    <xsl:for-each select="Entry">
                        <xsl:variable name="i" select="position()"/>
                        <xsl:variable name="elementName">
                            <xsl:choose>
                                <xsl:when test="$cols[$i]='Name'">
                                    <xsl:value-of select="'FirstName'"/>
                                </xsl:when>
                                <xsl:when test="$cols[$i]='Surname'">
                                    <xsl:value-of select="'LastName'"/>
                                </xsl:when>
                                <xsl:otherwise>
                                    <xsl:value-of select="$cols[$i]"/>
                                </xsl:otherwise>
                            </xsl:choose>
                        </xsl:variable>
                        <xsl:element name="{$elementName}">
                            <xsl:value-of select="."/>
                        </xsl:element>
                    </xsl:for-each>
                </Person>
            </xsl:for-each>
        </sampleResultXML>
    </xsl:template>
</xsl:stylesheet>

Answer 1

So I need a way to get the position of, let's say, the Title element dynamically. So I have to go through the Column elements until I reach the one with value "Title". This position I thought I'd save in a variable (e.g. Position_Title) so that I can fill the value later like so:

我觉得如果从相反的方向来做会简单很多。尝试：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/sampleSourceXML">
    <xsl:variable name="cols" select="Table/Header/Column" />
    <sampleResultXML>
        <xsl:for-each select="Table/Body/Row">
            <Person>
                <xsl:for-each select="Entry">
                    <xsl:variable name="i" select="position()" />
                    <xsl:element name="{$cols[$i]}">
                        <xsl:value-of select="."/>
                    </xsl:element>
                </xsl:for-each> 
            </Person>
        </xsl:for-each> 
    </sampleResultXML>
</xsl:template>

</xsl:stylesheet>

XSLT 1.0：如何根据值确定节点的位置

XSLT 1.0: How to determine the position of a node based on the value

xslt-1.0