"condition_monitoring_query_language" 的 Terraform 不支持的块类型错误

Question

我正在尝试在 terraform 中部署警报策略，但遇到了一个错误，指出此块不受支持。我发现这令人困惑，因为我使用了另一个名为 condition absent 的字段并且该策略运行良好。这是我要创建的 link 政策：google_monitoring_alert_policy

 Error: Unsupported block type

  on terraform/modules/google-monitoring-mql-alert-policy/main.tf line 29, in resource "google_monitoring_alert_policy" "default":
  29:       condition_monitoring_query_language  {

Blocks of type "condition_monitoring_query_language" are not expected here.

这是到目前为止的代码。这是从 condition_absent 到 condition_monitoring_query_language

的简单更改

    resource "google_monitoring_alert_policy" "default" {
  depends_on = [
    null_resource.is_ready
  ]

  display_name          = each.key
  project               = var.gcp_project
  enabled               = lookup(each.value, "enabled", true)
  combiner              = lookup(each.value, "combiner", "OR")
  notification_channels = lookup(each.value, "notification_channels", null) == null ? null : matchkeys(values(var.notificationlist), keys(var.notificationlist), lookup(each.value, "notification_channels", []))


  dynamic "conditions" {
    for_each = each.value["conditions"]

    content {
      display_name = conditions.key

      condition_monitoring_query_language  {
        query    = lookup(conditions.value, "query", null)
        duration = lookup(conditions.value, "duration", null)
        dynamic "trigger" {
          for_each = lookup(conditions.value, "trigger", [])
          content {
            count   = lookup(trigger.value, "count", null)
            percent = lookup(trigger.value, "percent", null)
          }
        }
      }
    }
  }

  dynamic "documentation" {
    for_each = lookup(each.value, "documentation", [])
    content {
      content   = lookup(documentation.value, "documentation_content", null)
      mime_type = lookup(documentation.value, "documentation_mime_type", null)
    }
  }

我应该怎么做才能成功 运行 我的“terraform 计划”？提前谢谢你

Answer 1

在 v3.46.0 中 添加了 基于

Monitoring Query Language 的警报。错误消息表明您使用的是旧版本。您必须升级您的 gcp 提供商。