在 CIFilter 内核中使用归一化采样器坐标

Question

我正在浏览有关自定义 CIFilter 的教程：

https://medium.com/@m_tuzer/using-metal-shading-language-for-custom-cikernels-metal-swift-7bc8e7e913e6

除了采样器的坐标未归一化外，一切正常。因此，例如 pos.y < 0.33 这样的条件不起作用，内核使用实际图像坐标。

由于教程是旧的，因此 CIFilter 中可能发生了“破坏”此代码的更改。我查看了 manual for CI kernels 但找不到获取内核内采样器标准化坐标的方法。

内核代码如下：

#include <metal_stdlib>
using namespace metal;
#include <CoreImage/CoreImage.h> // (1)

float3 multiplyColors(float3, float3);
float3 multiplyColors(float3 mainColor, float3 colorMultiplier) { // (2)
    float3 color = float3(0,0,0);
    color.r = mainColor.r * colorMultiplier.r;
    color.g = mainColor.g * colorMultiplier.g;
    color.b = mainColor.b * colorMultiplier.b;
    return color;
};

extern "C" { namespace coreimage {               // (3)
    float4 dyeInThree(sampler src, float3 redVector, float3 greenVector, float3 blueVector) {

        float2 pos = src.coord();
        float4 pixelColor = src.sample(pos);     // (4)
        
        float3 pixelRGB = pixelColor.rgb;
        
        float3 color = float3(0,0,0);
        if (pos.y < 0.33) {                      // (5)
            color = multiplyColor(pixelRGB, redVector);
        } else if (pos.y >= 0.33 && pos.y < 0.66) {
            color = multiplyColor(pixelRGB, greenVector);
        } else {
            color = multiplyColor(pixelRGB, blueVector);
        }

        return float4(color, 1.0);
    }
}}

Answer 1

您可以像这样使用源的范围将源坐标转换为相对值：

#include <metal_stdlib>
using namespace metal;
#include <CoreImage/CoreImage.h>


extern "C" { namespace coreimage {
    float4 dyeInThree(sampler src, float3 redVector, float3 greenVector, float3 blueVector) {

        float2 pos = src.coord();
        float4 pixelColor = src.sample(pos);

        // transform to relative coordinates
        pos -= src.origin();
        pos /= src.size();

        float3 color = float3(0,0,0);
        if (pos.y < 0.33) {
            color = pixelColor.rgb * redVector;
        } else if (pos.y < 0.66) {
            color = pixelColor.rgb * greenVector;
        } else {
            color = pixelColor.rgb * blueVector;
        }

        return float4(color, pixelColor.a);
    }
}}

在 CIFilter 内核中使用归一化采样器坐标

Using normalized sampler coordinates in CIFilter kernel

metal

core-image

cifilter

cikernel