通过 xslt 使用 rowspan 创建语义表

Question

我有以下 xml 文档：

...

<x>
<symptom><descr></descr></symptom>
<cause></cause>
<solution></solution>
<cause></cause>
<solution></solution>
</x>

...

在我的文档中有几个 <x>

在每个 <x> 中我只有一个 <symptom> 和 n <cause> 和 <solution> <cause> 和 <solution> 始终相同。

我想获得以下自动生成的结构：

<table>
<tr>
<td rowspan=count(cause)><xsl:value-of select="symptom/descr"></td>
<td><xsl:value-of select="cause"></td>
<td><xsl:value-of select="symptom"></td>
<tr>
<tr>
<td><xsl:value-of select="cause"></td>
<td><xsl:value-of select="symptom"></td>
<tr>
...
</table>

我试过下面的代码，我知道这是完全错误的。但是我被困了几个小时，在互联网上找不到任何好的解决方案。

    <xsl:for-each select="cause">
             <tr>
               <td rowspan="count(.)">
                 <xsl:value-of select="../descr[1]"/>
               </td>
               <td>
                 <xsl:value-of select="."/>
               </td>
               <xsl:for-each select="../solution">
                <td>
                 <xsl:value-of select="."/>
               </td>
</xsl:for-each>
 </tr>
             </xsl:for-each>
      </table>

Answer 1

这是基于您希望结果为 table 并具有以下结构的假设：给定示例输入 XML

<x>
  <symptom>
    <descr>
      Description
    </descr>
  </symptom>
  <cause>
    Cause 1
  </cause>
  <solution>
    Solution 1
  </solution>
  <cause>
    Cause 2
  </cause>
  <solution>
    Solution 2
  </solution>
</x>

我假设你想关注 table:

<table>
   <tr>
     <td rowspan="2">Description</td>
     <td>Cause 1</td>
     <td>Solution 1</td>
   </tr>
   <tr>
     <td>Cause 2</td>
     <td>Solution 2</td>
   </tr>
</table>

这可以通过以下 XSLT 完成：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="html"  omit-xml-declaration="yes" encoding="UTF-8" indent="yes" />
  <xsl:strip-space elements="*"/>
    <xsl:template match="x">
      <table>
        <xsl:for-each select="cause">
          <xsl:apply-templates select="." mode="row">
            <xsl:with-param name="amount" select="count(../cause)"/>
            <xsl:with-param name="position" select="position()"/>
          </xsl:apply-templates>
        </xsl:for-each>
      </table>
    </xsl:template>
    <xsl:template match="cause" mode="row">
    <xsl:param name="amount"/>
    <xsl:param name="position"/>
      <tr>
        <xsl:if test="$position = 1">
          <td rowspan="{$amount}">
              <xsl:value-of select="//symptom/descr"/>
          </td>
        </xsl:if>
        <td>
          <xsl:value-of select="."/>
        </td>
        <td>
          <xsl:value-of select="following-sibling::solution"/>
        </td>
    </tr>
  </xsl:template>
</xsl:transform>

通过应用模板为每个原因创建一行

<xsl:template match="cause" mode="row">

以行数和当前cause的位置作为参数。如果位置为1，则description被写为td中的值，cause的数量被写为rowspan的值。
每行包含当前值 cause:

<td>
  <xsl:value-of select="."/>
</td>

和solution在同一位置的值（solution即当前cause的following-sibling）：

<td>
  <xsl:value-of select="following-sibling::solution"/>
</td>

Answer 2

你在正确的线上，每个 cause 有一个 tr，这个怎么样：

<xsl:template match="x">
  <table>
    <xsl:for-each select="cause">
      <!-- the index of this cause within the list of causes in the current x -->
      <xsl:variable name="pos" select="position()" />
      <tr>
        <!-- first cause - create the spanning symptom cell -->
        <xsl:if test="$pos = 1">
          <td rowspan="{last()}"><xsl:value-of select="../symptom/descr"/></td>
        </xsl:if>
        <!-- this cause -->
        <td><xsl:value-of select="." /></td>
        <!-- the matching solution -->
        <td><xsl:value-of select="../solution[$pos]" /></td>
      </tr>
    </xsl:for-each>
  </table>
</xsl:template>

这里的一个技巧是last()函数，它returns当前for-each（或apply-templates）正在处理的节点总数，在这个大小写正是您要跨越的行数。

通过 xslt 使用 rowspan 创建语义表

Creating semantic tables with rowspan via xslt

html

xml

xslt