我不知道这个 xquery 代码中的语法错误

Question

let $d := doc('mondial.xml')
let $airports := $d/mondial/airport
let $countries := $d/mondial/country

for $data1 in $countries
    let $count :=xs:integer("0")
    let $name :=$data1/name
    let $car_code :=$data1/@car_code
    for $data2 in $airports
        where $car_code = $data2/@country 
            $count:= $count+ 1
    where xs:integer($count)>25 
        return
            <country>
                <name>{data($name)}</name>
                <count>{data($count)}</count>
            </country>

这是我的代码，当我运行这段代码时，有语法错误：错误：语法错误，意外的 $[err:XPST0003] $count:=$count+1

Answer 1

也许

let $d := doc('mondial.xml')
let $airports := $d/mondial/airport
let $countries := $d/mondial/country

for $country in $countries
  let $airport-count := count($airports[@country = $country/@car_code])
where $airport-count > 25
return
  <country>
  {
     $country/name,
     <count>{$airport-count}</count>
  }
  </country>

Answer 2

其实我找到了答案

let $d := doc('mondial.xml')
let $airports := $d/mondial/airport
let $countries := $d/mondial/country
for $data1 in $countries
    let $name :=$data1/name
    let $car_code :=$data1/@car_code
    let $count := count($airports[@country eq $car_code])   
    where $count>25     
        return
            <country>
                <name>{data($name)}</name>
                <count>{data($count)}</count>
            </country>

我不知道这个 xquery 代码中的语法错误

I don't know the syntax error in this xquery code

xquery