在 windows 上使用 cmd 减少文件名中的数字

Question

我有一堆文件：

CAR_003.dat
CAR_003.obj
CAR_004_prev0.png
CAR_004_prev1.png
CAR_004_tex0.tga

我需要将它们重命名为：

CAR_002.dat
CAR_002.obj
CAR_003_prev0.png
CAR_003_prev1.png
CAR_003_tex0.tga

如何在 windows 上使用 cmd 批量执行此操作？

Answer 1

您需要在您想要的目录中执行以下批处理。
它将重命名树中的所有内容。

@ECHO off
SETLOCAL EnableDelayedExpansion

FOR /R %%f in (CAR*) DO (
  FOR /F "usebackq tokens=1,2,* delims=_" %%m in ('%%~nxf') do (
    SET      filePath=%%~dpf
    SET    filePrefix=%%m_
    SET /a fileNumber=1%%~nn-1001
    SET    fileNumber=000!fileNumber!
    SET    fileNumber=!fileNumber:~-3!
    SET    filePosfix=%%~no
    SET       fileExt=%%~xf
    IF [!filePosfix!] EQU [] ( 
      SET    fileRest=%%~xf
    ) ELSE ( 
      SET    fileRest=_!filePosfix!!fileExt!
    )
    REM ECHO %%f
    REM ECHO !filePath!!filePrefix!!fileNumber!!fileRest!
    REM ECHO ~~~~~~~
    MOVE "%%f" "!filePath!!filePrefix!!fileNumber!!fileRest!"
  )
)

在 windows 上使用 cmd 减少文件名中的数字

decrement of a number in filename with cmd on windows

windows

batch-file

rename

decrement