为什么 FileAge 返回意外值？

Question

所以我有一个 'downloads' 文件夹，我把我在日常工作中下载的所有东西都放在这里。你知道我们总是将所有事情自动化，所以我正在尝试构建一个简单的应用程序来每天运行删除超过 30 天的文件，因为我必须不时手动执行此操作以避免文件夹变得太大.

这是我的代码：

function TForm1.deleteOldDownloads: boolean;
var
  f: string;
  i, d: Integer;
var
  sl: tstringlist;
begin
try
  FileListBox1.Directory := '\psf\home\downloads';
  FileListBox1.refresh;
  sl := tstringlist.create;
  for i := 0 to FileListBox1.items.count - 1 do
    begin
    f := FileListBox1.Directory + '\' + FileListBox1.items[i];
    if fileexists(f) then
      d := daysbetween(FileAge(f), now)
    else
      d := 0;
    if d > 30 then // problem is here, d is always a big number, not the actually age of file
      sl.Add(f);
    end;
  if sl.count > 0 then
    begin
    for i := 0 to sl.count do
      begin
      f := sl[i];
      deletefile(f);
      end;
    end;
  sl.Free;
except
  on e: Exception do
    begin     
    end;
end;

问题是“d”变量返回非常大的数字，如 1397401677，即使文件只有 1 天。

这里唯一的细节是我运行 Windows 在 Parallels 虚拟机中，“\psf\home\downloads”文件夹在 Mac 上，但我可以访问这个文件夹l通常使用 Windows 资源管理器，因此 Delphi 就像一个普通的本地文件夹。

我错过了什么？

Answer 1

您是否阅读了 FileAge 的 documentation？在编程学校的第一天，你被教导“当你开始使用一个新函数或 API 时，你首先要阅读它的文档。”在这种情况下，该函数的文档说

The [one-argument] overloaded version of FileAge is deprecated.

所以您正在使用不应该使用的功能。

不过，这个功能应该仍然可以使用。

但是您希望它达到什么目的 return？好吧，显然是文档所说的 return:

The first overload returns an integer that represents the OS time stamp of the file. The result can be later converted to a TDateTime using the FileDateToDateTime function.

但是当你在 DaysBetween 中使用它时，你假设它已经是 TDateTime!

Why is FileAge returning unexpected values?

不是。它可能 return 正是它的文档所说的 return。

Answer 2

您正在使用 FileAge() 的旧版本 returns DOS 数字格式的时间戳，但您将其视为 TDateTime，但事实并非如此。正如 FileAge documentation 所说：

The first overload returns an integer that represents the OS time stamp of the file. The result can be later converted to a TDateTime using the FileDateToDateTime() function.

所以，按照文档中的说明进行操作，例如：

var
  age: Integer;

age := FileAge(f);
if age <> -1 then
  d := DaysBetween(FileDateToDateTime(age), Now)

否则，使用输出 TDateTime 开头的较新版本的 FileAge()，例如：

var
  dt: TDateTime;

if FileAge(f, dt) then
  d := DaysBetween(dt, Now)

Answer 3

这不是对您问题的直接回答，但我不能post将其作为评论。所以，问题是，你永远不应该直接删除用户文件。如果你犯了错误怎么办？如果您的程序的用户犯了错误怎么办？始终将文件删除到回收站：

{--------------------------------------------------------------------------------------------------
   DELETE FILE
   Deletes a file/folder to RecycleBin.
   Old name: Trashafile
   Note related to UNC: The function won't move a file to the RecycleBin if the file is UNC. MAYBE it was moved to the remote's computer RecycleBin
--------------------------------------------------------------------------------------------------}
function RecycleItem(CONST ItemName: string; CONST DeleteToRecycle: Boolean= TRUE; CONST ShowConfirm: Boolean= TRUE; CONST TotalSilence: Boolean= FALSE): Boolean;
VAR
   SHFileOpStruct: TSHFileOpStruct;
begin
 FillChar(SHFileOpStruct, SizeOf(SHFileOpStruct), #0);
 SHFileOpStruct.wnd              := Application.MainForm.Handle;                                   { Others are using 0. But Application.MainForm.Handle is better because otherwise, the 'Are you sure you want to delete' will be hidden under program's window }
 SHFileOpStruct.wFunc            := FO_DELETE;
 SHFileOpStruct.pFrom            := PChar(ItemName+ #0);                                           { ATENTION!   This last #0 is MANDATORY. See this for details:   -   Although this member is declared as a single null-terminated string, it is actually a buffer that can hold multiple null-delimited file names. Each file name is terminated by a single NULL character. The last file name is terminated with a double NULL character ("[=10=][=10=]") to indicate the end of the buffer }
 SHFileOpStruct.pTo              := NIL;
 SHFileOpStruct.hNameMappings    := NIL;

 if DeleteToRecycle
 then SHFileOpStruct.fFlags:= SHFileOpStruct.fFlags OR FOF_ALLOWUNDO;

 if TotalSilence
 then SHFileOpStruct.fFlags:= SHFileOpStruct.fFlags OR FOF_NO_UI
 else
   if NOT ShowConfirm
   then SHFileOpStruct.fFlags:= SHFileOpStruct.fFlags OR FOF_NOCONFIRMATION;

 Result:= SHFileOperation(SHFileOpStruct)= 0;

 //DEBUG ONLY if Result<> 0 then Mesaj('last error: ' + IntToStr(Result)+ CRLF+ 'last error message: '+ SysErrorMessage(Result));
 //if fos.fAnyOperationsAborted = True then Result:= -1;
end;

此外，您不需要那个过时的控件来获取文件夹中的文件。你可以使用这个：

{ FIND FILES }
function ListFilesOf(CONST aFolder, FileType: string; CONST ReturnFullPath, DigSubdirectories: Boolean): TStringList;
{ If DigSubdirectories is false, it will return only the top level files,
  else it will return also the files in subdirectories of subdirectories.
  If FullPath is true the returned files will have full path.
  FileType can be something like '*.*' or '*.exe;*.bin'
  Will show also the Hidden/System files.
  Source Marco Cantu Delphi 2010 HandBook

   // Works with UNC paths}
VAR
  i: Integer;
  s: string;
  SubFolders, filesList: TStringDynArray;
  MaskArray: TStringDynArray;
  Predicate: TDirectory.TFilterPredicate;

   procedure ListFiles(CONST aFolder: string);
   VAR strFile: string;
   begin
    Predicate:=
          function(const Path: string; const SearchRec: TSearchRec): Boolean
          VAR Mask: string;
          begin
            for Mask in MaskArray DO
              if System.Masks.MatchesMask(SearchRec.Name, Mask)
              then EXIT(TRUE);
            EXIT(FALSE);
          end;

    // Long paths will raise an EPathTooLongexception exception, so we simply don't process those folders
    if Length(aFolder) > MAXPATH
    then exit;

    filesList:= TDirectory.GetFiles (aFolder, Predicate);
    for strFile in filesList DO
     if strFile<> ''                                                                                 { Bug somewhere here: it returns two empty entries ('') here. Maybe the root folder?  }
     then Result.Add(strFile);
   end;

begin
 { I need this in order to prevent the EPathTooLongexception (reported by some users) }
 if aFolder.Length >= MAXPATH then
  begin
   MesajError('Path is longer than '+ IntToStr(MAXPATH)+ ' characters!');
   EXIT(NIL);
  end;

 if NOT System.IOUtils.TDirectory.Exists (aFolder)
 then RAISE exception.Create('Folder does not exist! '+ CRLF+ aFolder);

 Result:= TStringList.Create;

 { Split FileType in subcomponents }
 MaskArray:= System.StrUtils.SplitString(FileType, ';');

 { Search the parent folder }
 ListFiles(aFolder);

 { Search in all subfolders }
 if DigSubdirectories then
  begin
   SubFolders:= TDirectory.GetDirectories(aFolder, TSearchOption.soAllDirectories, NIL);
   for s in SubFolders DO
    begin
     if ccIO.DirectoryExists(s)                                                                     { This solves the problem caused by broken 'Symbolic Link' folders }
     then ListFiles(s);
    end;
  end;

 { Remove full path }
 if NOT ReturnFullPath then
  for i:= 0 to Result.Count-1 DO
   Result[i]:= TPath.GetFileName(Result[i]);
end;

以上代码来自：https://github.com/GodModeUser/Delphi-LightSaber

为什么 FileAge 返回意外值？

Why is FileAge returning unexpected values?

delphi

delphi-10.4-sydney