在构建宏中获取抽象基础类型？

Question

例如我有一个抽象类型 Bool

abstract ABool(Bool) from Bool to Bool {}

我有一个那种类型的字段

var abool:ABool;

我需要知道我的构建宏中的 ABool 底层类型 (Bool)。

Answer 1

#if macro
import haxe.macro.Expr;
import haxe.macro.*;
#end

class Builder {
    macro static public function build():Array<Field> {
        var fields = Context.getBuildFields();
        for (f in fields) {
            switch (f.kind) {
                // looks at class variables and properties
                case FVar(t, e) | FProp(_, _, t, e):
                    // t is a haxe.macro.ComplexType,
                    // lets convert it to a haxe.macro.Type,
                    // such that we can check if it is an abstract type or not
                    var type = Context.typeof(macro {var a:$t; a;});
                    switch (type) {
                        case TAbstract(t, params):
                            var underlyingType = t.get().type;
                            trace(underlyingType); //TAbstract(Bool,[])
                        case _:
                            // ignore things that are not of abstract type
                    }
                case _:
                    // ignore methods
            }
        }
        return fields;
    }
}

abstract ABool(Bool) from Bool to Bool {}

#if !macro
@:build(Builder.build())
#end
class Test {
    var abool:ABool;

    static function main() {

    }
}

在构建宏中获取抽象基础类型？

Get abstract underlying type in a build macro?

macros

haxe