Delphi 记录作业

Question

我遇到了 delphi XE3 编译器的一些奇怪行为（我为 x86 架构编译）。

假设我 class 有一个字段 - 自定义记录有几个简单类型的字段：

  TPage = class
  type
    TParagraph = record
    public
      FOwner:  TPage;

      FFirst:  Integer;
      FSecond: Integer;

      procedure Select;
    end;
  public
    FSelected: TParagraph;
  end;

procedure TPage.TParagraph.Select;
begin
  FOwner.FSelected:=Self;
end;

逻辑是我的页面可以包含多个段落，在某些时候我希望选择其中一个段落（以便能够在我的程序的其他部分使用它执行一些操作）：

procedure TMainForm.Button1Click(Sender: TObject);
var
  lcPage:      TPage;
  lcParagraph: TPage.TParagraph;
begin
  lcPage:=TPage.Create;
  try
    <...>

    lcParagraph.FOwner:=lcPage;
    lcParagraph.FFirst:=1;
    lcParagraph.FSecond:=2;

    lcParagraph.Select;

    <...>
  finally
    lcPage.Free;
  end;

当我的记录不超过某个大小时一切正常。一个引用和两个整数就可以了，在这种情况下，我得到这样的汇编程序指令：

MainUnit.pas.350: FOwner.FSelected:=Self;
00C117B3 8B45FC           mov eax,[ebp-]
00C117B6 8B00             mov eax,[eax]
00C117B8 8B55FC           mov edx,[ebp-]
00C117BB 8B0A             mov ecx,[edx]
00C117BD 894804           mov [eax+],ecx
00C117C0 8B4A04           mov ecx,[edx+]
00C117C3 894808           mov [eax+],ecx
00C117C6 8B4A08           mov ecx,[edx+]
00C117C9 89480C           mov [eax+[=13=]c],ecx

我可以看到三个正确的 movs，它们将内存从本地记录复制到 class`。

但是！如果我向我的记录添加更多字段，生成的 asm 代码会发生变化并且记录分配不再正确执行。

    TParagraph = record
    public
      FOwner:  TPage;

      FFirst:  Integer;
      FSecond: Integer;
      FThird:  Integer;

      procedure Select;
    end;

MainUnit.pas.350: FOwner.FSelected:=Self;
00C117C9 8B45FC           mov eax,[ebp-]
00C117CC 8B55FC           mov edx,[ebp-]
00C117CF 8B12             mov edx,[edx]
00C117D1 8BF2             mov esi,edx
00C117D3 8D7A04           lea edi,[edx+]
00C117D6 A5               movsd 
00C117D7 A5               movsd 
00C117D8 A5               movsd 
00C117D9 A5               movsd

然后我在 class' 记录 FSelected 中得到垃圾：

lea 指令后 CPU 状态是这样的：

在此示例中，02D37280 是我的 lcPage class 的地址，因此 02D37284 应包含其字段的开头 - FSelected 记录。但是 movsd 指令将内存从 ESI 复制到 EDI，从 02D37280 复制到 02D37284，这绝对没有意义！如果我将 ESI 寄存器更改为 EAX (19F308) 的值，这是我本地 lcParagraph 变量的开始，则复制会正确执行：

我描述的是已知错误吗？还是我遗漏了一些关于 delphi 的基本信息？这是分配记录的好方法吗？我可以很容易地解决这个问题，例如，将 procedure TPage.TParagraph.Select; 中的 FOwner.FSelected:=Self; 更改为 CopyMemory(@FOwner.FSelected, @Self, SizeOf(Self));。但我想弄清楚哪里出了问题。

最小可重现示例：

program RecordAssignmentIssue;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

type
  TPage = class
  type
    TParagraph = record
    public
      FOwner:  TPage;

      FFirst:  Integer;
      FSecond: Integer;
      FThird:  Integer;

      procedure Select;
    end;
  public
    FSelected: TParagraph;
  end;

procedure TPage.TParagraph.Select;
begin
  FOwner.FSelected:=Self;
end;

var
  lcPage:      TPage;
  lcParagraph: TPage.TParagraph;
begin
  try
    lcPage:=TPage.Create;
    try
      lcParagraph.FOwner:=lcPage;
      lcParagraph.FFirst:=1;
      lcParagraph.FSecond:=2;
      lcParagraph.FThird:=3;

      lcParagraph.Select;

      Assert(CompareMem(@lcPage.FSelected, @lcParagraph, SizeOf(lcParagraph)));
      // get rid of FThird and assertion will pass
    finally
      lcPage.Free;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Answer 1

这是 Delphi 11 中仍然存在的错误（感谢 ). You should submit a bug report to Quality Portal。

与此同时，我认为您可以通过在 TPage 而不是 TParagraph 中进行赋值来解决这个问题。像这样：

program RecordAssignmentIssue;

{$APPTYPE CONSOLE}

uses
  System.SysUtils;

type
  TPage = class
  type
    TParagraph = record
    public
      FOwner:  TPage;

      FFirst:  Integer;
      FSecond: Integer;
      FThird:  Integer;

      procedure Select;
    end;
  private
    procedure Select(const Paragraph: TParagraph);
  public
    FSelected: TParagraph;
  end;

procedure TPage.TParagraph.Select;
begin
  FOwner.Select(Self);
end;

{ TPage }

procedure TPage.Select(const Paragraph: TParagraph);
begin
  FSelected:=Paragraph;
end;

var
  lcPage:      TPage;
  lcParagraph: TPage.TParagraph;

begin
  try
    lcPage:=TPage.Create;
    try
      lcParagraph.FOwner:=lcPage;
      lcParagraph.FFirst:=1;
      lcParagraph.FSecond:=2;
      lcParagraph.FThird:=3;

      lcParagraph.Select;

      Assert(CompareMem(@lcPage.FSelected, @lcParagraph, SizeOf(lcParagraph)));
      // get rid of FThird and assertion will pass
    finally
      lcPage.Free;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

或者另一个非常简单的解决方法是引入一个额外的局部指针变量来保存指向 Self:

的指针

procedure TPage.TParagraph.Select;
var
  P: ^TParagraph;
begin
  P := @Self;
  FOwner.FSelected := P^;
end;

Delphi 记录作业

Delphi records assignment

delphi

delphi-xe3