绘图中的错误比例

Question

只有一个图，比例是正确的，即在 [0,100]:

之间

当我使用超过 1 个绘图时，缩放比例错误：

//@version=4
study(title="test", overlay=false)

src  = input(close, title="Index Source")
v1 = security("OANDA:EURUSD", timeframe.period, src)
v2 = security("OANDA:USDJPY", timeframe.period, src)
v3 = security("OANDA:GBPUSD", timeframe.period, src)

Length = input (8, minval=1, title = "Stochastic Length")
k = input (3, minval=1, title = "Stochastic %K")
StoV1 = stoch (v1, highest(Length), lowest(Length), Length)
StoV2 = stoch (v2, highest(Length), lowest(Length), Length)
StoV3 = stoch (v3, highest(Length), lowest(Length), Length)
Kv1 = sma (StoV1, k)
Kv2 = sma (StoV2, k)
Kv3 = sma (StoV3, k)
plot (Kv1, title  ="%K", color = color.black, linewidth=2)
plot (Kv2, title  ="%K", color = color.blue, linewidth=2)
plot (Kv3, title  ="%K", color = color.red, linewidth=2)

关于如何解决这个问题有什么想法吗？

Answer 1

它按图表中的最大值缩放，蓝色图以百万为单位，红色以千为单位，黑色为小数。

Answer 2

跟你有多少地块无关。这取决于您所在的图表。当您在具有高价值（BTC）的图表上时，您的价值似乎以百万计。当您在图表上显示低值 (EURUSD) 时，您的值并没有那么高。

我发现这很奇怪，因为你的绘图值不应该根据你所在的图表而改变。玩了一会儿，我发现你的代码有错误。

StoV1 = stoch (v1, highest(Length), lowest(Length), Length)
StoV2 = stoch (v2, highest(Length), lowest(Length), Length)
StoV3 = stoch (v3, highest(Length), lowest(Length), Length)

根据文档，当您将 highest() 和 lowest() 与一个参数一起使用时，它将使用 high/low 作为函数的来源。

One arg version: x is a length. Algorithm uses high as a source series.

但是，high/low 属于您所在的图表。因此，当您更改这对时，您的绘图值会有所不同。

您需要做的是，使用 security() 从要分析的对中检索 high 和 low 值，并在计算中使用这些值。

//@version=4
study(title="test", overlay=false)

src  = input(close, title="Index Source")
v1 = security("OANDA:EURUSD", timeframe.period, src)
v2 = security("OANDA:USDJPY", timeframe.period, src)
v3 = security("OANDA:GBPUSD", timeframe.period, src)

h1 = security("OANDA:EURUSD", timeframe.period, high)
h2 = security("OANDA:USDJPY", timeframe.period, high)
h3 = security("OANDA:GBPUSD", timeframe.period, high)

l1 = security("OANDA:EURUSD", timeframe.period, low)
l2 = security("OANDA:USDJPY", timeframe.period, low)
l3 = security("OANDA:GBPUSD", timeframe.period, low)

Length = input (8, minval=1, title = "Stochastic Length")
k = input (3, minval=1, title = "Stochastic %K")
StoV1 = stoch (v1, highest(h1, Length), lowest(l1, Length), Length)
StoV2 = stoch (v2, highest(h2, Length), lowest(l2, Length), Length)
StoV3 = stoch (v3, highest(h3, Length), lowest(l3, Length), Length)
Kv1 = sma (StoV1, k)
Kv2 = sma (StoV2, k)
Kv3 = sma (StoV3, k)
plot (Kv1, title  ="%K", color = color.black, linewidth=2)
plot (Kv2, title  ="%K", color = color.blue, linewidth=2)
plot (Kv3, title  ="%K", color = color.red, linewidth=2)

改变你的图表对，你会发现你的值是一致的。缩放似乎也可以。

绘图中的错误比例

Wrong scaling in plot

plot

pine-script