使用宏将所有形状转换为Ms word中的图像

Question

我写这个宏来将文档中的所有形状转换为图像:

Sub AllShapeToPic()    
   For Each oShp In ActiveDocument.Shapes
    oShp.Select
    Selection.Cut
    Selection.PasteSpecial Link:=False, DataType:=wdPasteEnhancedMetafile, _
        Placement:=wdInLine, DisplayAsIcon:=False
   Next oShp

End Sub

但是当我运行它时，none 个形状转换为图像。
我的宏代码有什么问题？

Answer 1

欢迎来到操纵您正在循环浏览的集合的奇妙世界。在您剪切的那一刻，您实际上是在从集合中删除形状，从而改变您的循环。

如果您想遍历形状（或 table 行或其他）并从该集合中删除某些内容，只需向后退：

Dim i As Integer, oShp As Shape

For i = ActiveDocument.Shapes.Count To 1 Step -1
    Set oShp = ActiveDocument.Shapes(i)
    oShp.Select
    Selection.Cut
    Selection.PasteSpecial Link:=False, dataType:=wdPasteEnhancedMetafile, _
        Placement:=wdInLine, DisplayAsIcon:=False
Next i

或者表 （警告：未经测试！）

Dim tbl As Table

For i = ActiveDocument.Tables.Count To 1 Step -1
    Set tbl = ActiveDocument.Tables(i)
    tbl.Select
    Selection.Cut
    Selection.PasteSpecial Link:=False, dataType:=wdPasteEnhancedMetafile, _
        Placement:=wdInLine, DisplayAsIcon:=False
Next i

对于方程式：方程式是 InlineShapes 并且具有 "OMath" 属性。用它来识别方程对象。 警告：未经测试

Dim equation As InlineShape

For i = ActiveDocument.InlineShapes.Count To 1 Step -1
    Set equation = ActiveDocument.InlineShapes(i)
    If equation.OMath > 0 Then
        equation.Select
        Selection.Cut
        Selection.PasteSpecial Link:=False, dataType:=wdPasteEnhancedMetafile, _
            Placement:=wdInLine, DisplayAsIcon:=False
    End If
Next i

使用宏将所有形状转换为Ms word中的图像

Convert all shape to image in Ms word with macro

vba

ms-word

ms-office