根据 XSLT 中的条件计算行项目的总和

Question

我需要通过添加每行的重量+计数来计算毛重。但我需要检查每个项目中的级别段。
如果项目只有一个级别 - Level=1 我应该同时添加 Weight+Count。但如果项目有多个 - level - Level=1 和 Level=2 那么它应该只需要权重。

在示例中 XML 第一项是单级的，第二项是多级的。所以总应该是
<第一项> - (10+4)+(10+4)+(10+4)
<第二项> - 10+10+20+20+20
总毛重 = 122

是否可以考虑具有上述条件的每一行并添加总毛额重量。我真的找不到任何方法来实现这一目标。如果有任何可能的解决方案，请帮助！

<?xml version="1.0" encoding="UTF-8"?>
<Main>
<Item>
  <Line>
    <Level>1</Level>
    <Weight>10</Weight>
    <Count>4</Count>
  </Line>
  <Line>
    <Level>1</Level>
    <Weight>10</Weight>
    <Count>4</Count>
  </Line>
  <Line>
    <Level>1</Level>
    <Weight>10</Weight>
    <Count>4</Count>
  </Line>
</Item>

<Item>
  <Line>
    <Level>1</Level>
    <Weight>10</Weight>
    <Count>8</Count>
  </Line>
  <Line>
    <Level>1</Level>
    <Weight>10</Weight>
    <Count>8</Count>
  </Line>
  <Line>
    <Level>2</Level>
    <Weight>20</Weight>
    <Count>10</Count>
  </Line>
  <Line>
    <Level>2</Level>
    <Weight>20</Weight>
    <Count>10</Count>
  </Line>
  <Line>
    <Level>2</Level>
    <Weight>20</Weight>
    <Count>10</Count>
  </Line>
</Item>
</Main>

    <?xml version="1.0" encoding="utf-8"?>
    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" 
        xmlns:xs="http://www.w3.org/2001/XMLSchema" 
        xmlns:fo="http://www.w3.org/1999/XSL/Format"
        >
    
    <xsl:output method="xml" indent="yes"/>
    
    <xsl:template match="Main" >   
        <root>
         <xsl:call-template name="Template1">
             <xsl:with-param name="NodeList" select="Item/Line"/>    
         </xsl:call-template>
        </root>
    </xsl:template>
    
    
    
    <xsl:template  name ="Template1">  
        <xsl:param name="NodeList" />
        
        
        <xsl:for-each select="$NodeList">
            <Group>
                <xsl:value-of select="(Weight)+(Count)" />
             </Group>
        </xsl:for-each>  
        
     </xsl:template>
    </xsl:stylesheet>

Answer 1

好吧，这是您可以查看的一种方式：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/Main">
    <result>
        <xsl:call-template name="process-items">
            <xsl:with-param name="items" select="Item"/>
        </xsl:call-template>
    </result>
</xsl:template>

<xsl:template name="process-items">
    <xsl:param name="items"/>
    <xsl:param name="total" select="0"/>
    <xsl:choose>
        <xsl:when test="$items">
            <xsl:variable name="item" select="$items[1]"/>
            <xsl:variable name="amount">
                <xsl:choose>
                    <xsl:when test="not($item/Line/Level != $item/Line/Level)">
                    <!-- single level -->
                        <xsl:value-of select="sum($item/Line/Weight) + sum($item/Line/Count)" />
                    </xsl:when>
                    <xsl:otherwise>
                    <!-- multi-level -->
                        <xsl:value-of select="sum($item/Line/Weight)"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:variable>
            <!-- recursive call -->
            <xsl:call-template name="process-items">
                <xsl:with-param name="items" select="$items[position() > 1]" />
                <xsl:with-param name="total" select="$total + $amount" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$total"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

另一种方法已在您的中展示：计算变量中的单个项目值，然后对结果求和。

根据 XSLT 中的条件计算行项目的总和

calculate the sum of line items depending on condition in XSLT

xslt-1.0